Excel - сложное сопоставление индексов для поиска нескольких значений

Question

Я пытаюсь сделать довольно сложный поиск в таблице и вернуть несколько значений.

Мне нужно взять каждый ID как группу, если Service Code не содержит плюс или если он содержит исключение, игнорируйте его. Если Sales и Service не совпадают, игнорируйте их. Все остальное мне нужно вывести в список.

Я в пути над головой и даже не знаю, с чего начать.

---

Другими словами, в службе Plus Sales и Service не могут совпадать, если не было сделано исключение . Данные A, B, C не имеют значения, но они есть.

Answer 1

Это более гибкое решение, чем VBA, но в некоторой степени гибридное ручное управление.

Добавьте столбец TRUE/FALSE под названием "Обслуживается продажами"

=C2=D2

Затем другой столбец TRUE/FALSE под названием "Имеет исключение"

=COUNTIFS(A:A, A2, B:B, "Exception")

Тогда вы просто отфильтруете таблицу, в которой Serviced by Sales = TRUE и Has exception = FALSE . Чтобы получить список, вы должны скопировать и вставить идентификаторы в другое место и запустить « Data > Remove Duplicates .

Если вы ожидаете создания отчетов в режиме реального времени, я бы остановился на решении VBA.

Answer 2

Если я вас правильно понял, вам нужен список, как указано выше, за исключением того, что вы хотите исключить идентификационные коды, если служебные коды идентификатора не содержат плюс. Кроме того, если продажи и обслуживание не совпадают, они не должны включаться - ЕСЛИ в коде обслуживания есть exception .

Вы думали о вспомогательных столбцах?

Самый простой способ сделать это - объединить столбцы A+B в столбце E, в котором вы получите ряд номеров идентификаторов и служебных кодов.

Затем вы можете использовать инструкцию countif в строке E, чтобы проверить, где ID и PLUS = true .

Затем вам нужно будет проверить имена и исключения.

Затем вы можете использовать вложенный оператор IF для проверки совпадений, исключений и плюсов.

В E это, очевидно, будет =CONCATENATE(a2,b2)

F будет выглядеть так =if(countif(E:E,CONCATENATE(a2,"PLUS"))>0,"PLUS","")

G вам нужно использовать для проверки имен - так что вам нужно идти с =Concatenate(a2,if(c2=d2,"Match","ERROR")

H вам нужно использовать, чтобы проверить, что все имена в порядке или существует исключение.

=if(and(countif(g:G,concatenate(a2,"ERROR")>0,NOT(countif(e:e,concatenate(a2,"EXCEPTION")>0))),"No match","match")

наконец, в I вы можете найти, где Plus = Plus и имя соответствует = Match

=IF(AND(F2="Plus",H2="Match"),"Include","Exclude")

Это (если мои формулы верны - ymmmv!) должен позволить вам затем отфильтровать список по "INCLUDE" и т. д. Voila, вашему списку ID где service и sale либо Exception либо совпадение, и при аренде одна из записей кода услуги ID содержит plus

Answer 3

Хорошо, я принял вызов для VBA. Я немного запутался в том, что вы хотели, когда присутствует Exception , поэтому в настоящее время, если есть исключение, он полностью пропустит эту группу. Дайте мне знать, если это не то поведение, которое вы хотели. Возможно, вы правы в том, что формула существует и, вероятно, делает ее глупо чрезмерно сложной. Надеюсь, это может кому-то помочь!

Sub CalculateList()
    Dim startRowCount As Integer: startRowCount = 2     'Row to start on
    Dim columnId As Integer: columnId = 1               'Column containing ID
    Dim OutputColumn As Integer: OutputColumn = 7       'Column to output into

    '------ Begin

    Cells(1, OutputColumn).Select                       'Selects the output cell, incase there are any successes

    Dim rowCount: rowCount = startRowCount              'Sets our start row count for the loop
    Dim RowsContainingId()                              'Array containing the row ID's matching the current ID of the loop
    ReDim RowsContainingId(1)
    Dim CompletedIds()                                  'Array containing the ID's that have already been done
    ReDim CompletedIds(1)

    Do                                                  'Begin loop
nextNumberStart:                                        'Label to go back to if we hit an already completed ID
        Dim CurrentID As String: CurrentID = Cells(rowCount, columnId).Value            'Get the CurrentID of this loop
        If (CurrentID = "") Then                        'If we hit a blank, we're done, so...
            Exit Do                                     'Exit the loop
        End If
        If (IsInArray(CurrentID, CompletedIds)) Then    'Check if this ID has already been handled
            rowCount = rowCount + 1                     'It has, so select the next row
            GoTo nextNumberStart:                       '...And begin the loop again
        End If

        GetAllMatchingRowIds CurrentID, RowsContainingId, startRowCount, columnId   'Runs sub lower down to populate the array with all the rows with this ID
        If (TestIdMeetsCriteria(RowsContainingId)) Then     'Test these rows to see if it meets your criteria (function below)
            ActiveCell.Value = CurrentID                'It's a success, so write this ID in our active cell
            ActiveCell.Offset(1, 0).Activate            'And select the cell one row down, ready to write again if needed
        End If


        CompletedIds(UBound(CompletedIds) - 1) = CurrentID      'Add this ID to our completed list
        ReDim Preserve CompletedIds(UBound(CompletedIds) + 1)   'Grow our array one more ready for next completed item

        Erase RowsContainingId                          'Wipe out our Matching ID array for next loop
        ReDim RowsContainingId(1)
        rowCount = rowCount + 1
    Loop
End Sub

Function IsInArray(stringToBeFound As String, arr As Variant) As Boolean
  IsInArray = (UBound(Filter(arr, stringToBeFound)) > -1)           'Checks if a string is in the array
End Function

Function TestIdMeetsCriteria(arr As Variant) As Boolean
    Dim row
    Dim HasException, ValidPlus: HasException = False: ValidPlus = False        'Set our bools to False
    For Each row In arr                                             'Loop through each row containing our ID
        If (LCase(Cells(row, 2).Value) = "plus") Then               'Check for "Plus" (case insensitively)
            If (LCase(Cells(row, 3).Value) = LCase(Cells(row, 4).Value)) Then   'We got Plus, do we have matching Service and Sales (case insensitive)?
                ValidPlus = True                                    'We do. Set ValidPlus to true for comparison later
            End If
        ElseIf (LCase(Cells(row, 2).Value) = "exception") Then      'Now check if any rows contains Exception (case insensitive)
            HasException = True                                     'We do. Set HasException to true for later comparison
        End If
    Next
    TestIdMeetsCriteria = Not (HasException) And ValidPlus          'We finished the loop. If HasException is still false, and ValidPlus is now true, it was a success, otherwise a failure
End Function

Sub GetAllMatchingRowIds(idToFind As String, arr As Variant, startRowId As Integer, columnId As Integer)
    Dim rowCount: rowCount = startRowId
    Do                                                          'Loop through our ID column rows
        If (Cells(rowCount, columnId).Value = idToFind) Then    'Check if the ID is the one we're after
            arr(UBound(arr) - 1) = rowCount                     'It is, add it to our array
            ReDim Preserve arr(UBound(arr) + 1)                 'Grow our array for next lop
        End If
        rowCount = rowCount + 1                                 'Next row
    Loop Until IsEmpty(Cells(rowCount, columnId).Value)         'Keep looping until we hit a blank
    ReDim Preserve arr(UBound(arr) - 2)                         'Remove additional entries in array we don't need
End Sub

Результат: