Excel: какие значения увеличивать, а какие нет в автозаполнении

Question

Я пытаюсь создать кодировщик слов, в котором есть столбец, в который вы вводите буквы, и столбец, на который будут ссылаться в функции, которая определяет букву и кодирует ее. Это моя функция:

=IF(A1 = "A", D1, IF(A1 = "B", D2, IF(A1 = "C", D3, IF(A1 = "D", D4, IF(A1 = "E", D5, IF(A1 = "F", D6, IF(A1 = "G", D7, IF(A1 = "H", D8, IF(A1 = "I", D9, IF(A1 = "J", D10, IF(A1 = "K", D11, IF(A1 = "L", D12, IF(A1 = "M", D13, IF(A1 = "N", D14, IF(A1 = "O", D15, IF(A1 = "P", D16, IF(A1 = "Q", D17, IF(A1 = "R", D18, IF(A1 = "S", D19, IF(A1 = "T", D20, IF(A1 = "U", D21, IF(A1 = "V", D22, IF(A1 = "W", D23, IF(A1 = "X", D24, IF(A1 = "Y", D25, IF(A1 = "Z", D26, "0"))))))))))))))))))))))))))

Столбец D - это то, что я хотел бы использовать в качестве ссылки. Мне нужно, чтобы он автоматически заполнял третий столбец (закодированный столбец) 26 раз, но только увеличивал A1 до A2, затем A3 вниз по столбцу, не увеличивая D1, D2 и D3 до D2, D3 и D4 как Я автоматически заполняю столбец.

Есть ли способ заблокировать значения D так, чтобы увеличивались только значения A?

Answer 1

Могу ли я предложить несколько более короткую формулу, чем 26 вложенных IF:

=INDEX($D$1:$D$26,FIND(A1,"ABCDEFGHIJKLMNOPQRSTUVWXYZ"))

Скопируйте вниз.

Ссылка на $ D $ 1:$ D $ 26 использует знаки $, поэтому она не изменится при копировании. Ссылка на A1 является относительной и при копировании изменится на A2, A3 и т.д.

Answer 2

Если вы поместите доллар перед буквой или цифрой, он заблокирует его, чтобы он не изменился при автозаполнении, что даст вам:

=IF(A1 = "A", $D$1, IF(A1 = "B", $D$2, IF(A1 = "C", $D$3, IF(A1 = "$D$", $D$4, IF(A1 = "E", $D$5, IF(A1 = "F", $D$6, IF(A1 = "G", $D$7, IF(A1 = "H", $D$8, IF(A1 = "I", $D$9, IF(A1 = "J", $D$10, IF(A1 = "K", $D$11, IF(A1 = "L", $D$12, IF(A1 = "M", $D$13, IF(A1 = "N", $D$14, IF(A1 = "O", $D$15, IF(A1 = "P", $D$16, IF(A1 = "Q", $D$17, IF(A1 = "R", $D$18, IF(A1 = "S", $D$19, IF(A1 = "T", $D$20, IF(A1 = "U", $D$21, IF(A1 = "V", $D$22, IF(A1 = "W", $D$23, IF(A1 = "X", $D$24, IF(A1 = "Y", $D$25, IF(A1 = "Z", $D$26, "0"))))))))))))))))))))))))))

Тем не менее, похоже, что вы использовали вложенные операторы if, чтобы сделать то, что уже является встроенной функцией, чтобы преуспеть. Если вы поместите таблицу, подобную следующей, вы можете просто использовать =vlookup(A1,$E$1:$F$26,2,FALSE) и получить тот же результат.

|COL E|COL F|
| A   |your |
| B   |     |
| C   |subs-|
| D   |titu-|
| E   |tions|
| F   |     |
| G   | go  |
| H   |     |
| I   |here |
| J   |     |
| K   |     |
| L   |     |
| M   |     |
| N   |     |
| O   |     |
| P   |     |
| Q   |     |
| R   |     |
| S   |     |
| T   |     |
| U   |     |
| V   |     |
| W   |     |
| X   |     |
| Y   |     |
| Z   |     |

Кроме того, используйте клавишу F4 при вводе ссылки, чтобы переключаться между параметрами абсолютной ссылки, не вводя доллар (A1, $ A1, A $ 1 и $ A $ 1).

Answer 3

Если я правильно понимаю вопрос, вам нужно использовать $ в ссылках на ячейки, чтобы указать части ссылок на ячейки, которые будут абсолютными и относительными.

Например:

Копирование формулы =A1+1 вниз (или поперек) соответственно.

Однако если бы мы всегда хотели использовать A1, вы бы использовали = $A$1 +1

$ Можно использовать в одной или обеих позициях в зависимости от того, что вам нужно. Возможно, вы захотите только =$A1 или =A$1 зависимости от того, что вы делаете, и в каком направлении (вниз или поперек) вы справляетесь.

Вы можете найти больше информации здесь.