Команда для поиска сетевого интерфейса для IP

Question

С помощью ipconfig я могу показать список сетевых адаптеров и их настройки, например, IP-адрес.

Я ищу обратную команду, которая отображает имя сетевого адаптера для данного IP-адреса.

Я попытался отфильтровать вывод ipconfig с помощью команды, подобной ipconfig | find "192.168.2.4" но имя адаптера пропало.

Мой вывод ipconfig (сложная часть кажется, что у меня есть несколько адресов на одном адаптере здесь):

Windows IP Configuration


Ethernet adapter Local Area Connection:

   Connection-specific DNS Suffix  . :
   Link-local IPv6 Address . . . . . : fe80::xxxx:xxxx:xxxx:xxxx%11
   IPv4 Address. . . . . . . . . . . : 192.168.2.4
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   IPv4 Address. . . . . . . . . . . : 192.168.178.20
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   Default Gateway . . . . . . . . . : 192.168.178.1
                                       192.168.2.1

Ethernet adapter VMware Network Adapter VMnet1:
...

score 7 · Accepted Answer · 2011-03-09T19:38:42

Как отобразить имя сетевого адаптера для данного IP-адреса?

Это решение не требует никаких внешних команд (pcre2grep , sed и т.д.).

Используйте следующий пакетный файл (getname.cmd):

@echo off
setlocal
setlocal enabledelayedexpansion
set "_adapter="
set "_ip="
for /f "tokens=1* delims=:" %%g in ('ipconfig /all') do (
  set "_tmp=%%~g"
  if "!_tmp:adapter=!"=="!_tmp!" (
    if not "!_tmp:IPv4 Address=!"=="!_tmp!" (
      for %%i in (%%~h) do (
      if not "%%~i"=="" set "_ip=%%~i"
      )
    set "_ip=!_ip:(Preferred)=!"
    if "!_ip!"=="%1" (
        @echo !_adapter!
      )
    )
  ) else (
    set "_ip="
    set "_adapter=!_tmp:*adapter =!"
  )
)
endlocal

Использование:

getname ipaddress

Пример:

F:\test>getname 192.168.42.78
Local Area Connection 2
F:\test>

Дальнейшее чтение

Индекс AZ командной строки Windows CMD - Отличный справочник по всем вопросам, связанным с командной строкой Windows.
for /f - Циклическая команда против результатов другой команды.
ipconfig - настройка IP (настройка интернет-протокола)

score 6 · Answer 2 · 2011-03-09T19:38:42

Вы можете использовать этот PS один вкладыш:

$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}

Чтобы использовать его прямо из командной строки:

powershell "$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}"

или если вы хотите использовать его повторно, поместите его в скрипт и сделайте адрес параметром

Изменить: чтобы получить имя, как показано в Win/Ipconfig:

$addr='192.168.2.4'; 
$netconf = get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr};
$netconf |% {$_.GetRelated("win32_NetworkAdapter")} | select NetConnectionID |%{$_.NetConnectionID}

(присваивание промежуточным переменным только для того, чтобы сделать его немного более читабельным)

score 4 · Answer 3 · 2011-03-09T19:38:42

Я ищу обратную команду, которая отображает имя сетевого адаптера для данного IP-адреса.

Исходя из всего, что я пробовал, это должно сработать, кажется, вы говорите, что вам нужно получить эту информацию ТОЛЬКО с IP-адреса, который вы уже указали в своем примере.

ИНТЕРАКТИВНАЯ ПОДСКАЗКА ДЛЯ IP-АДРЕСА, ЧТОБЫ ПОЛУЧИТЬ ИМЯ СОЕДИНЕНИЯ СЕТИ

(Используйте WMIC и некоторый пакетный FOR цикла token и разбор delim чтобы получить имя сетевого подключения для указанного IP-адреса.)

(Значение результата отобразится в окне команд и окне сообщений. Это все пакетный сценарий, но динамически создает некоторые функции сценария VBS, чтобы упростить процесс для всех, кто нуждается.)

@ECHO ON

:SetTempFiles
SET tmpIPaddr=%tmp%\~tmpipaddress.vbs
SET tmpNetConName1=%tmp%\~tmpNetConName1.txt
SET tmpNetConName2=%tmp%\~tmpNetConName2.txt
SET tmpBatFile=%tmp%\~tmpBatch.cmd
SET tmpVBNetCon=%tmp%\~tmpVBNetCon.vbs

IF EXIST "%tmpIPaddr%" DEL /F /Q "%tmpIPaddr%"
IF EXIST "%tmpNetConName1%" DEL /Q /F "%tmpNetConName1%"
IF EXIST "%tmpNetConName2%" DEL /Q /F "%tmpNetConName2%"
IF EXIST "%tmpBatFile%" DEL /Q /F "%tmpBatFile%"
IF EXIST "%tmpVBNetCon%" DEL /Q /F "%tmpVBNetCon%"

:InputBox
SET msgboxTitle=IP ADDRESS
SET msgboxLine1=Enter the IP address to get its Windows connection name
>"%tmpIPaddr%" ECHO wsh.echo inputbox("%msgboxLine1%","%msgboxTitle%")
FOR /F "tokens=*" %%N IN ('cscript //nologo "%tmpIPaddr%"') DO CALL :setvariables %%N
GOTO EOF

:setvariables
SET IPAddress=%~1
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%A IN (`"WMIC NICCONFIG GET IPADDRESS,MACADDRESS /FORMAT:CSV | FIND /I "%IPAddress%""`) DO (SET MACAddress=%%~A)
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%B IN (`"WMIC NIC GET MACADDRESS,NETCONNECTIONID /FORMAT:CSV | FIND /I "%MACAddress%""`) DO ECHO(%%~B>>"%tmpNetConName1%"

::: Parse Empty Lines
FINDSTR "." "%tmpNetConName1%">"%tmpNetConName2%"

::: Build Dynamic Batch with ECHO'd Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO ECHO ECHO %%~C>>"%tmpBatFile%"
IF NOT EXIST "%tmpBatFile%" GOTO :NullExit
START "" "%tmpBatFile%"

::: Build Dynamic VBS with Message Box Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO (SET vbNetconName=%%~C)
ECHO msgbox "%vbNetconName%",0,"%vbNetconName%">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

:NullExit
ECHO msgbox "Cannot find MAC Address, check to confirm IP Address was correct.",0,"Invalid IP">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

ВСЕ ОДИН ЛАЙНЕРЫ

РОДНЫЕ ОКНА ТОЛЬКО С NETSH ВСЕМИ ИНТЕРФЕЙСАМИ (ВСЕ АДРЕСА IPv4)

NETSH INT IP SHOW CONFIG | FINDSTR /R "Configuration for interface.* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

РОДНЫЕ ОКНА ТОЛЬКО С IPCONFIG ВСЕМИ ИНТЕРФЕЙСАМИ (ВСЕ АДРЕСА IPv4)

IPCONFIG | FINDSTR /R "Ethernet* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

ИСПОЛЬЗОВАНИЕ PCRE2GREP (для @SalvoF)

УДЕЛЬНЫЙ IP-АДРЕС УКАЗАН

netsh interface ipv4 show address | pcre2grep -B2 "192\.168\.2\.4" | FIND /V "DHCP"

НАЙТИ ВСЕ IP-АДРЕСА

netsh interface ip show config | pcre2grep -B2 ^(?:[0-9]{1,3}\.){3}[0-9]{1,3}$ | FIND /V "DHCP" | FIND /V "Gate" | FIND /V "Metric" | FIND /V "Subnet"

НАЙТИ ВСЕ IP-АДРЕСА (очищенное регулярное выражение (для @SalvoF))

netsh interface ip show config | pcre2grep "^[A-Z]|IP.*([0-9]{1,3}(\.|)){4}"

Пожалуйста, обратите внимание, что pcre2grep я пробовал, соответствует @SalvoF [+1] как он предложил, но используя .... FIND /V для удаления строки выше, содержащей DHCP похоже, дает желаемый результат, как вы описали. Я использовал NETSH а не IPCONFIG .

score 3 · Answer 4 · 2011-03-09T19:38:42

Чтобы быть более точным, следуя примеру OP, я бы использовал sed , который можно найти в папке \usr\local\wbin этого заархивированного файла (проект UnxUtils).

ipconfig | sed -rn "/^[A-Z]/h;/192.168.2.4/{g;s/.* adapter (.*):/\1/p;}"

-n подавляет несовпадающие строки; первый шаблон находит любую строку, начинающуюся с заглавной буквы, затем h убирает ее на пробел; второе совпадение - по требуемому IP-номеру: в этот момент имя интерфейса, содержащее строку, вызывается (g), лишний лишний текст (s) отбирается и печатается (p).

score 2 · Answer 5 · 2011-03-09T19:38:42

Для справки, вот еще одно пакетное решение, в котором используется отложенное расширение системной переменной %ERRORLEVEL% :

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%L in ('ipconfig') do (
    echo %%L | findstr /r "^[A-Z]" 1>NUL
    if !errorlevel! == 0 set "_int=%%L"
    echo %%L | findstr /c:%1 1>NUL
    if !errorlevel! == 0 (
       set "_int=!_int::=!"
       echo !_int:* adapter =!
       goto:eof
    )
)

Он может быть вызван следующим образом: find_int.cmd 192.168.1.100

score 1 · Answer 6 · 2011-03-09T19:38:42

Спасибо за усилия всем. Кажется, есть несколько препятствий:

количество IP-адресов, назначенных адаптеру
язык ОС

Все вещи -Bx и Regex, кажется, легко ломаются, поэтому я нашел что-то, что мог бы реализовать сам, и предложил следующую программу на C #, которая принимает IP-адрес в качестве параметра (IP2Adapter <IP>):

using System;
using System.Net.NetworkInformation;
using System.Net.Sockets;

namespace IP2Adapter
{
    class Program
    {
        static void Main(string[] args)
        {
            var adapters = NetworkInterface.GetAllNetworkInterfaces();
            foreach (var adapter in adapters)
            {
                var ipProps = adapter.GetIPProperties();
                foreach (var ip in ipProps.UnicastAddresses)
                {
                    if ((adapter.OperationalStatus == OperationalStatus.Up)
                        && (ip.Address.AddressFamily == AddressFamily.InterNetwork))
                    {
                        if (ip.Address.ToString() == args[0])
                        Console.Out.WriteLine(adapter.Name);
                    }
                }
            }
        }
    }
}

Сейчас выбран русский

Команда для поиска сетевого интерфейса для IP

6 ответов6

Как отобразить имя сетевого адаптера для данного IP-адреса?

Дальнейшее чтение

ВСЕ ОДИН ЛАЙНЕРЫ

ИСПОЛЬЗОВАНИЕ PCRE2GREP (для @SalvoF)

Всё ещё ищете ответ? Посмотрите другие вопросы с метками windows networking ip batch-file ip-address.

Команда для поиска сетевого интерфейса для IP

6 ответов6

Как отобразить имя сетевого адаптера для данного IP-адреса?

Дальнейшее чтение

ВСЕ ОДИН ЛАЙНЕРЫ

ИСПОЛЬЗОВАНИЕ PCRE2GREP (для @SalvoF)

Всё ещё ищете ответ? Посмотрите другие вопросы с метками windows networking ip batch-file ip-address.

Похожие