Я использую AutoHotkey для обмена Ctrl и Alt
LAlt::LCtrl
LCtrl::LAlt
Это прекрасно работает, но помимо этого я хочу сохранить Alt+Tab и Ctrl+Tab, где они были изначально.
Я уже пробовал много разных фрагментов кода, но пока ни один из них не сработал.
Наиболее близким к полностью работающему решению, но только для Alt+Tab и без Shift+Alt+Tab, является https://stackoverflow.com/questions/18454895/using-auto-hotkey-to-swap-ctrl -alt-и орудие-Ctrl-Tab
Понял, это работает сейчас!
Это было в правильном направлении, но с кодом было несколько проблем. Особенно LShift не проверялся, если он был ложным, поэтому первое утверждение всегда было верным.
Я также добавил поддержку Ctrl+Tab.
*tab::
{
if (GetKeyState("LAlt", "P") AND GetKeyState("LShift", "P") = false) {
Send {LControl up}{LAlt down}{tab}
KeyWait, tab
} else if (GetKeyState("LAlt", "P") AND GetKeyState("LShift", "P")) {
Send {LControl up}{LShift down}{LAlt down}{tab}
KeyWait, tab
} else if (GetKeyState("LCtrl", "P") AND GetKeyState("LShift", "P") = false) {
Send {LAlt up}{LCtrl down}{tab}
KeyWait, tab
} else if (GetKeyState("LCtrl", "P") AND GetKeyState("LShift", "P")) {
Send {LAlt up}{LShift down}{LCtrl down}{tab}
KeyWait, tab
} else if (GetKeyState("LWin", "P") AND GetKeyState("LShift", "P") = false) {
Send {LWin down}{tab}
KeyWait, tab
} else if (GetKeyState("LWin", "P") AND GetKeyState("LShift", "P")) {
Send {LShift down}{LWin down}{tab}
KeyWait, tab
} else {
send {tab}
}
return
}
~LAlt Up::
{
send {LAlt up}
return
}
~LCtrl Up::
{
send {LCtrl up}
return
}
LAlt::LCtrl
LCtrl::LAlt
Поскольку я работаю только на примере кода, приведенного в ответе, на который вы ссылаетесь, я собрал приведенный ниже код. Я не знаю, какое действие выполняет «Shift +Alt +Tab», так как я не получаю ответа от него на моей системе, так что вам придется проверить меня, чтобы убедиться, что это дает желаемый эффект.
*tab::
{ if (GetKeyState("LAlt", "P"))
{ Send {LControl up}{Alt down}{tab}
KeyWait, tab
}else if (GetKeyState("LAlt", "P")) AND (GetKeyState("LShift", "P"))
{ Send {LControl up}{LShift down}{Alt down}{tab}
KeyWait, tab
}else
{ send {tab}
}
return
}
~LAlt Up::
{ send {lAlt up}
return
}
LAlt::LCtrl
LCtrl::LAlt
Для меня версия @herkulano не надежна на Windows10. Иногда запускаются разные ключи, и я не могу работать.
Вместо этого я использую это, которое также работает с Emacs для таких комбинаций, как C-M-- .
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn ; Enable warnings to assist with detecting common errors.
; The .ahk text file needed to be saved with UTF8-BOM encoding rather than UTF8
; https://stackoverflow.com/questions/15635635/how-do-i-use-unicode-in-autohotkey
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
global sendLAltUpOnLCtrlUp := 0
;; https://superuser.com/questions/984343/remap-ctrl-to-alt-and-keep-alttab-and-ctrltab/1332713#1332713
;; https://autohotkey.com/board/topic/96465-switch-alt-and-ctrl-retain-alt-tab/
;; Let LCtrl sends LWin, LWin sends LAlt and LAlt sends LCtrl using SharpKeys and then
*tab::
{
if (GetKeyState("LCtrl", "P") AND GetKeyState("LShift", "P") = false) {
sendLAltUpOnLCtrlUp := 1
Send {LCtrl up}{LAlt down}{tab}
KeyWait, tab
} else
if (GetKeyState("LCtrl", "P") AND GetKeyState("LShift", "P")) {
sendLAltUpOnLCtrlUp := 1
Send {LCtrl up}{LShift down}{LAlt down}{tab}
KeyWait, tab
}
else {
send {tab}
}
return
}
~LCtrl up::
{
if(sendLAltUpOnLCtrlUp == 1) {
sendLAltUpOnLCtrlUp := 0
send {LAlt up}
} else {
send {LCtrl up}
}
return
}
~LAlt up::
{
send {LAlt up}
return
}
;; Example how to insert polish diactrics with `RAlt + Shift + A` etc.
;; https://pl.m.wikipedia.org/wiki/Alfabet_polski
>!+a::Send {U+0104}
>!a::Send {U+0105}
Поместите это в отдельный .ahk :
SendMode Input
*LAlt::
send {LCtrl down}
Keywait, Lalt
send {LCtrl up}
return
*LCtrl::
send {Lalt down}
Keywait, LCtrl
send {Lalt up}
return
И это в другом .ahk
SendMode Input
LAlt & Tab::
send {Lalt down}{Tab}
return
+esc::Exitapp
Затем запустите оба сценария (сначала запустите первый).
Мне очень понравилась версия @ rofrol, но она обрабатывает отправку Alt(+Shift)+Tab только при нажатии Ctrl(+Shift)+Tab.
Я также хотел инвертировать, Ctrl(+Shift)+Tab, когда нажаты Alt(+Shift)+Tab.
Кроме того, он нарушил простую функциональность Shift+Tab, которую я использую все время во время кодирования, поэтому я добавил дополнительное условие, чтобы это исправить.
global sendLAltUpOnLCtrlUp := 0
global sendLCtrlUpOnLAltUp := 0
*tab::
{
if (GetKeyState("LCtrl", "P") AND GetKeyState("LShift", "P"))
{
sendLAltUpOnLCtrlUp := 1
Send {LCtrl up}{LShift down}{LAlt down}{tab}
KeyWait, tab
}
else if (GetKeyState("LCtrl", "P"))
{
sendLAltUpOnLCtrlUp := 1
Send {LCtrl up}{LAlt down}{tab}
KeyWait, tab
}
else if (GetKeyState("LAlt", "P") AND GetKeyState("LShift", "P"))
{
sendLCtrlUpOnLAltUp := 1
Send {LAlt up}{LShift down}{LCtrl down}{tab}
KeyWait, tab
}
else if (GetKeyState("LAlt", "P"))
{
sendLCtrlUpOnLAltUp := 1
Send {LAlt up}{LCtrl down}{tab}
KeyWait, tab
}
else if (GetKeyState("LShift", "P"))
{
Send {LShift down}{tab}
KeyWait, tab
}
else
{
send {tab}
}
return
}
~LCtrl up::
{
if(sendLAltUpOnLCtrlUp == 1)
{
sendLAltUpOnLCtrlUp := 0
send {LAlt up}
}
else
{
send {LCtrl up}
}
return
}
~LAlt up::
{
if(sendLCtrlUpOnLAltUp == 1)
{
sendLCtrlUpOnLAltUp := 0
send {LCtrl up}
}
else
{
send {LAlt up}
}
return
}