Несколько формул в ячейке с условием IF

Question

Я пытаюсь выяснить, как я могу вставить несколько формул в одну ячейку. Расчет относится к дате и времени.

Ниже мои вопросы.

Если A1 = Дата и B1 = Время (военные) И C1 = Дата и D1 = Время (военные), чтобы получить разницу во времени в часах, я использую приведенную ниже формулу в F1.

=((C1+D1)-(A1+B1))*24

Что мне нужно сделать, это чтобы F1 определил, нет ли значения в A1 и B1, чем использовать функцию =now() для завершения формулы. Другими словами, мне нужна следующая формула.

=(now()-(A1+B1))*24

или что-то в этом роде.

Я начинающий с Excel и мне нужно это, чтобы создать отчет измерения времени.

Answer 1

Первый вопрос: какое именно состояние вы хотите проверить?  Я думаю ты хочешь

OR(ISBLANK(C1), ISBLANK(D1))

или же

OR(C1="", D1="")

что означает почти то же самое - что либо C1 либо D1 не заполнены.  Другие возможности включают

• AND(ISBLANK(C1), ISBLANK(D1))

  или же

  AND(C1="", D1="")

• ISBLANK(C1)

  или же

  C1=""

  с ожиданием, что пустой D1 будет рассматриваться как 00:00 .

• (C1+D1)=0

  что в значительной степени эквивалентно AND(C1="", D1="") .

Как только вы выбрали свое условие, функция IF довольно проста.  Решение "грубой силы" будет

=IF(OR(C1="",D1=""), (NOW()-(A1+B1))*24, ((C1+D1)-(A1+B1))*24)

Но вы можете переместить общие части снаружи:

=(IF(OR(C1="",D1=""), NOW(), C1+D1) - (A1+B1)) *24

Answer 2

Excel уже вполне способен хранить даты и время точно так, как вам нужно - вам не нужно умножать на 24 и т.д. Если вы просто format ячейки как Даты или Времена, они будут автоматически отображаться в виде часов и минут. (1,0 = 24 часа, 0,5 = 12 часов и т.д.)

Но я думаю, что формула, которую вы ищете, должна быть:

=IF((A1+B1)>0,now()-A1+B1,0)

Эта формула проверяет, является ли сумма A1 и B1 больше нуля, а затем возвращает вашу формулу. В противном случае возвращается ноль. Если вы отформатировали ячейку для отображения времени, то этот ноль может отображаться как 00:00, что, по-видимому, и является тем, что вы просите.