Как определить количество параметров в командном файле и просмотреть их?

Question

Есть ли простой способ определить количество параметров, переданных в качестве аргументов в пакетный файл, а затем использовать for /L для их циклического прохождения?

Answer 1

Как определить количество параметров в командном файле и просмотреть их?

%* в пакетном скрипте ссылается на все аргументы (например,% 1% 2% 3% 4% 5 ...% 255)

Вы можете использовать %* для извлечения всех аргументов командной строки в командный файл.

Чтобы подсчитать аргументы и выполнить цикл с for /L см. Ответ StackOverflow Batch-Script - Итерация по аргументам aacini:

@echo off
setlocal enabledelayedexpansion

set argCount=0
for %%x in (%*) do (
   set /A argCount+=1
   set "argVec[!argCount!]=%%~x"
)

echo Number of processed arguments: %argCount%

for /L %%i in (1,1,%argCount%) do echo %%i- "!argVec[%%i]!"

---

Дальнейшее чтение

• Индекс AZ командной строки Windows CMD - Отличный справочник по всем вопросам, связанным с командной строкой Windows.
• for - Условно выполнить команду несколько раз.
• параметры - аргумент командной строки (или параметр) - это любое значение, переданное в пакетный скрипт:

Answer 2

В целом @DavidPostill имеет правильный ответ. Это не увидит /? хотя переключается (и, возможно, несколько других). Если вы хотите увидеть их, вы можете использовать: for %%x in ("%*") do ( вместо for %%x in (%*) do ( . Проблема в том, что эта версия не увидит ничего в кавычках. Если вы хотите версию, которая может сделать и то, и другое, то вот гораздо менее простой ответ:

@set @junk=1 /*
@ECHO OFF
:: Do not changes the above two lines. They are required in order to make the 
:: JScript below work.

:: In order to get the parameter count from WSH we will call this script 
:: three times in three different ways. The first time, it'll run the code in this
:: section just as any normal BATCH script would. At the end of this section, it'll 
:: call cscript.exe in order to run the JScript portion below.

:: The final call will be the same call as was originally requested but with the 
:: difference of the first parameter being the word redux (if that is a possible 
:: valid value for your script then you'll want to change it here and in the 
:: JScript below as well).
IF "%1" == "redux" @GOTO :CLOSINGTIME

:: The next step passes this script to get the WSH command line executable for 
:: further processing.
cscript //nologo //E:jscript %~f0 %*

:: Exit the initial call to this script.
GOTO:EOF */

// We are now in the second iteration of the call. Here we are using JScript 
// instead of batch because WSH is much better at counting it's parameters.

var args=WScript.Arguments, 
    sh=WScript.CreateObject("WScript.Shell"),
    cmd="%comspec% /k " + WScript.ScriptFullName + ' redux ' + args.length;

for(var i=0, j=args.length; i<j; i++)
    cmd+=' "' + args(i) + '"';

// sh.Popup("The generated command line is:\n  "+cmd);

var exec=sh.Exec(cmd);
while(!exec.StdOut.AtEndOfStream)
  WScript.Echo(exec.StdOut.ReadLine());

// Leave the script now. Remember that the entire script needs to be parsable by
// WSH so be sure that anything after this line is in the comment below.
WScript.Quit(0);

/* This line is here to hide the rest of the file from WSH.
========================================================================

:CLOSINGTIME

:: Now we've called this script 3 times (once manually and now twice more just
:: to get back here knowing the correct argument count. We've added that value
:: to the command line so lets remove that cruft before we call this done.

:: Remove the static, redux, parameter
SHIFT

:: Save the argument count.
SET ARGC=%1

:: Remove ARGC parameter
SHIFT

:: Now you are ready to use your batch code. The variable %ARGC% contains the
:: argument count of the original call.


:: ******************************
:: ** START OF YOUR BATCH CODE **
:: ******************************

ECHO Fancy JScript count: %ARGC%
ECHO.

:: ****************************
:: ** END OF YOUR BATCH CODE **
:: ****************************

:: This is needed in order to let the JScript portion know that output has ended.
EXIT

:: ========================================================================
:: This line will hide everything in your second BATCH portion from WSH. */

К сожалению, это также не идеальный ответ из-за способа, которым мы должны были выполнить файл из WSH, StdErr и StdOut оба не работают для окончательного сценария. Вы можете исправить StdErr в определенных ситуациях, используя 2&>1 в конце второго пакетного вызова: var exec=sh.Exec(cmd+" 2&>1"); StdIn должен быть обработан как особый случай для каждого скрипта.