Ошибка синтаксической команды

Question

Ошибка "Синтаксис команды неверен" всегда появляется каждый раз, когда я собираюсь запустить этот командный файл. Я не могу понять, какая часть скрипта вызывает эту ошибку. Любая идея?

rem Process all *.tif files in input path
pushd "%in_path%"
for %%a in (*.tif) do (
   set "fileName=%%a"
   rem If the YearDay in this file is the same of previous one
   if "!fileName:~1,7!" equ "!yearDay!" (
      rem Join this filename to previous list
      set "fileList=!fileList!!fileName! "
      set /A numFiles+=1
   ) else (
      rem Merge the files in the list if there are more than 3, in the out_path leaving only TYYYYDDD.L2_LAC.Tera.tif
      if !numFiles! gtr 3 (
         gdal_merge.py -n 0 -a_nodata -32767 -of GTiff -o %out_path%\T!yearDay!.L2_LAC.Tera.tif !fileList!
         rem Move processed files to a different directory
         set "fileList=!fileList:~0,-1!"
         move !fileList: =,! "%proc_path%"
      )
      rem And start a new YearDay and fileList
      set "yearDay=!fileName:~1,7!"
      set "fileList=!fileName! "
      set numFiles=1
   )
)
popd

Answer 1

Разобрался с помощью друга. Я только что заменил эту часть сценария,

 set "fileList=!fileList:~0,-1!"
 move !fileList: =,! "%proc_path%"

с этим,

for %%a in (!fileList!) do move %%a "%proc_path%"  >nul