Как я могу рассчитать строку в формуле? сделать ссылку на конкретную ячейку

Question

Например: ссылка на ячейку A1 - " =A1 "
А - название столбца
1 - номер строки

Можно ли рассчитать номер строки в формулах, чтобы сделать конкретные ссылки?
Что-то вроде =A{some calculations} поэтому =A{1+1} будет ссылкой для ячейки A2

Answer 1

=INDEX(A1:A100,1,2)       [this will give you row 1, column B]

ИЛИ ЖЕ

=INDEX(A1:Z100,1+1,2+2)   [this will give you row 2, column D]

= INDEX (TARGET:AREA, ROW, COLUMN)

Если вы используете тонны таких, как я. Индексы не будут задерживать ваши документы. Косвенное и смещение поглощают ОЧЕНЬ больше ресурсов. Загрузите несколько тысяч косвенных адресов или смещений, и ваши документы начнут тянуться со всей обслуживаемой волатильностью.

Очевидно, вы можете упаковать его различными способами, такими как:

=INDEX(A1:Z100,ROW(A1)+1,COLUMN(B1)+2)  

Answer 2

Да, но это делается
=OFFSET(Start_Cell, Rows_Up_or_Down, Columns_Right_or_Left [, Number_of_Rows [, Number_of_Columns]])
Итак, предположим, что ваша информация начинается с C5, и вы хотите, чтобы 1 ячейка была внизу на 4 строки и справа на 2 столбца:
=OFFSET(C5,4,2)

Answer 3

Есть несколько способов сделать это в Excel. Ответ LDC3 описывает OFFSET. Другой это:

    =INDIRECT(reference,style)

Это создает ссылку на ячейку из текстовой записи. Это дает большую свободу для вычисления или создания ссылки на ячейку.

    =INDIRECT("A"&(1+1))   is equivalent to =A2
    =INDIRECT("A"&ROW())   if this formula is in cell C5, 
                           this would be equivalent to =A5

Если параметр style равен TRUE или пропущен, он предполагает нормальное форматирование ссылки на ячейку, как указано выше.

INDIRECT также допускает другой стиль спецификации строк и столбцов. Если параметром стиля является "FALSE", он использует R#C# где вы используете букву R чтобы указать, что следующее число является номером строки, и буква C чтобы указать, что следующее число является номером столбца (все указано в виде чисел ). Если вы опустите число после R или C , предполагается, что вы имеете в виду текущую строку или столбец.

    =INDIRECT("R1C1",FALSE)    is equivalent to =A1
    =INDIRECT("R"&(ROW()-4)&"C",FALSE) if this formula is in cell C5, 
                                       this would be equivalent to =C1 
                                       (current column, and row number equal to 
                                        the current row -4).

Этот формат позволяет рассчитывать ссылки на строки и столбцы в виде чисел. Он также функционирует как OFFSET, но относительно текущего местоположения, а не якорной ячейки. Если вы поставите число в квадратных скобках, это означает относительное положение (количество строк или столбцов вдали от текущей ячейки).

    =INDIRECT("R3C[-2]",FALSE)  if this formula is in cell C5, 
                                this would be equivalent to =A3