Как заставить QuickTime открываться на втором мониторе?

Question

Когда я запускаю фильм в QuickTime, я бы хотел, чтобы он всегда отображался на моем втором дисплее (а не по умолчанию). Я на самом деле открываю фильм через AppleScript из iTunes, чтобы было приемлемо решение appleScript.

Раньше в Quicktime была настройка предпочтений, которая позволяла бы использовать ее по умолчанию для определенного дисплея, но, похоже, она была потеряна в QuickTime X.

Answer 1

Итак, я пошел дальше и захватил границы окна, расположенного в середине моего второго экрана, и просто добавил строку в мой AppleScript, чтобы каждый раз выдвигать новое окно.

tell application "iTunes"
    set sel to item 1 of selection
    set loc to (get location of sel)
end tell

tell application "QuickTime Player"
    open loc
    activate
    set bounds of front window to {2460, 256, 3299, 736}
    present front document
    play front document
end tell

Теперь из iTunes я могу выбрать нужный фильм, запустить сценарий, и QuickTime откроет его на полном экране на втором мониторе и начнет его воспроизведение. Еще больше взломано вместе, чем хотелось бы, но пока подойдет, я полагаю.

Answer 2

http://forums.macosxhints.com/showthread.php?t=59812 содержит код для отправки всех окон приложения на второй монитор. Вы можете либо запустить код в Quicktime Player, либо, возможно, извлечь соответствующую логику второго монитора и запустить ее в одном окне.

Зеркальный код здесь, для потомков:

tell application "System Events"
    --  set visible of process "Untitled" to false -- don't use name extension
    --  delay 1
    set Name_App to item 1 of (get name of processes whose frontmost is true)
end tell

-- broken
--tell (do shell script "defaults read /Library/Preferences/com.apple.windowserver | grep -w Width") to set {monitor1_width, monitor2_width} to {word 3 as number, word 6 as number}
-- fixed by:
set {monitor1_width, monitor2_width} to {1280, 1024}

--tell (do shell script "defaults read /Library/Preferences/com.apple.windowserver | grep -w Height") to set {monitor1_height, monitor2_height} to {word 3 as number, word 6 as number}


tell application Name_App
    try
        set {x, y, xx, yy} to bounds of front window
        set The_Scriptable to true
    on error
        set The_result to my get_position(Name_App)
        if The_result is {} then return
        set {x, y} to The_result
        set The_Scriptable to false
    end try
    if The_Scriptable then
        if x <= monitor1_width and xx >= monitor1_width then -- the window is in the first monitor
            if xx > monitor2_width then set xx to monitor2_width
            set New_bounds to {monitor1_width + x, y, monitor1_width + xx, yy}
        else if x >= monitor1_width then -- the window is in the second monitor
            if xx - x > monitor1_width then
                set xx to monitor1_width
            else
                set xx to xx - x
            end if
            set New_bounds to {x - monitor1_width, y, xx, yy}
        else
            --the window is between the monitors
        end if
        set bounds of front window to New_bounds
    else
        if x <= monitor1_width then -- the window is in the first monitor
            set new_Position to {monitor1_width + x, y}

        else -- the window is in the second monitor
            set new_Position to {x - monitor1_width, y}
        end if
        tell application "System Events" to tell process Name_App to set position of front window to new_Position
    end if
    tell front window to "Zoom"

end tell

on get_position(This_App)
    try
        tell application "System Events" to tell process This_App
            return position of front window
        end tell
    on error
        return {}
    end try
end get_position

Answer 3

Я знаю, что когда я запускал установку с двумя мониторами, он запоминал вещи, которые были у меня на втором мониторе, даже если у меня не было его подключения. Если вы перетащите окно в этот экран, вы сможете обучить его вспомнить, чтобы поместить его туда.

Answer 4

По-видимому, QT X, поставленный с 10.6, не завершен. Там должна быть дополнительная установка, чтобы переустановить старую версию QT с установочного диска SL. Не похоже, что QT X позволяет вам устанавливать полноэкранный монитор по умолчанию.