Как "Ответить всем" и сохранить исходное вложение в Outlook?

Question

Как я могу выполнить "Ответить всем" в Outlook, но отправить исходное вложение обратно всем?

Answer 1

Очевидно не без некоторого кода VBA. Вот кое-что, что я нашел, чтобы сделать именно это. (Источник)

Описание: этот образец Outlook VBA создает и отображает ответ на открытое или выбранное в настоящий момент сообщение, включая вложения в оригинале.

Sub ReplyWithAttachments()
    Dim rpl As Outlook.MailItem
    Dim itm As Object

    Set itm = GetCurrentItem()
    If Not itm Is Nothing Then
        Set rpl = itm.Reply
        CopyAttachments itm, rpl
        rpl.Display
    End If

    Set rpl = Nothing
    Set itm = Nothing
End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application

    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select

    Set objApp = Nothing
End Function

Sub CopyAttachments(objSourceItem, objTargetItem)
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
   strPath = fldTemp.Path & "\"
   For Each objAtt In objSourceItem.Attachments
      strFile = strPath & objAtt.FileName
      objAtt.SaveAsFile strFile
      objTargetItem.Attachments.Add strFile, , , objAtt.DisplayName
      fso.DeleteFile strFile
   Next

   Set fldTemp = Nothing
   Set fso = Nothing
End Sub

Примечания к коду:

1. Использует функцию GetCurrentItem() чтобы вернуть текущий выбранный или отображаемый элемент.

2. Использует процедуру CopyAttachments() для копирования вложений в ответ.

3. Заменить itm.Reply с itm.ReplyAll если вы предпочитаете отвечать всем.

(О, и я нашел это приблизительно через 30 секунд, делая поиск в сети по запросу "ответить всем с вложениями в outlook").

Answer 2

Возможное решение:

Человек, который отправляет это сообщение в первый раз, открывает свою папку "Отправленные", открывает сообщение и снова выбирает « Действия» - «Повторно отправить это сообщение ....» .