Excel 2007 VBA Экспорт диапазона в виде JPG-файла работает над картиной

Question

У меня есть рабочая тетрадь с различными диапазонами данных с 77 строками и более. Мне нужно скопировать их и сохранить в виде файлов JPG, которые будут использоваться другим приложением.

Ниже приведен пример кода, который я использую для этого. Он отлично работает для диапазонов до 68 строк, но для диапазонов с более чем этим, файл показывает высоту диапазона до 1360 пикселей, а остальная часть (нижняя часть) - белая.

Sub Create_jpg() Dim MyPath As String Dim rgExp As Range

MyPath = ThisWorkbook.Path & "\ScorecardJPEGs\"

Sheets("LocalMetrics").Select

Set rgExp = Range("A1:AL77")

rgExp.CopyPicture Appearance:=xlScreen, Format:=xlBitmap

With ActiveSheet.ChartObjects.Add(Left:=rgExp.Left, Top:=rgExp.Top, _
                                  Width:=(rgExp.Width - 10), Height:=(rgExp.Height - 5))
    .Name = "ChartTempEXPORT"
    .Activate
End With

ActiveChart.Paste
ActiveSheet.ChartObjects("ChartTempEXPORT").Chart.Export FileName:=MyPath & "Scorecard.jpg", _
                                                         Filtername:="jpg"
ActiveSheet.ChartObjects("ChartTempEXPORT").Delete

End Sub

Я проверил, что создание диаграммы и вставка выглядят хорошо, так как я удалил строку кода, которая удаляет диаграмму в конце, и, очевидно, изображение на диаграмме было в порядке. Но когда файл создан, нижняя часть картинки просто исчезла, и там есть пробел. Это случилось со всеми диапазонами со многими рядами.

Answer 1

Из того, что я могу сказать, ваш диапазон вставки больше, чем ваше пространство вставки. Я не мог получить Excel, чтобы получить пустое пространство, которое вы описали, но следующий код сделал это так, чтобы макрос мог обрабатывать более 77 строк.

Sub Create_jpg()
Const fColumn As String = "A": Const lColumn As String = "AL"
Const maxRange As Integer = 77
Dim tempRowEnd As Integer: tempRowEnd = 0: Dim tempRowBegin As Integer: tempRowBegin = 0
Dim loopCount As Integer: loopCount = 0
Dim MyPath As String
Dim rgExp As Range
Dim lRowCount As Long:
MyPath = ThisWorkbook.Path & "\ScorecardJPEGs\"
Sheets("Sheet1").Select
lRowCount = Worksheets("Sheet1").UsedRange.Rows.Count
Do
    tempRowBegin = tempRowEnd + 1 'chooses the first row in the selection
    tempRowEnd = tempRowEnd + maxRange 'chooses the end row in the selection
    Set rgExp = Range(fColumn & tempRowBegin & ":" & lColumn & tempRowEnd)

    rgExp.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
    With ActiveSheet.ChartObjects.Add(Left:=rgExp.Left, Top:=rgExp.Top, _
                                  Width:=(rgExp.Width - 10), Height:=(rgExp.Height - 5))
        .Name = "ChartTempEXPORT"
        .Activate
    End With

    ActiveChart.Paste
    ActiveSheet.ChartObjects("ChartTempEXPORT").Chart.Export Filename:=MyPath & "Scorecard" & loopCount & ".jpg", _
                                                     Filtername:="jpg"
    ActiveSheet.ChartObjects("ChartTempEXPORT").Delete

    loopCount = loopCount + 1 'increments count for naming convention
Loop Until tempRowEnd > lRowCount

End Sub

Дайте мне знать, как это работает для вас.