Контроль импорта CSV в Excel 2010

Question

У меня есть CSV с такими значениями:

"очень длинное значение с запятой", "387621937291732193"

Число, несмотря на то, что оно заключено в кавычки, превращается в число в Excel и отображается в научной записи. Как вы мешаете Excel предположить, что все является числом? Почему в Excel не отображаются какие-либо параметры при открытии файла CSV, как для файлов .txt?

Answer 1

Вы можете добавить = в начало числовой строки:

"a very long value, with a comma",="387621937291732193"

Обновить

Если вы не можете изменить CSV, у вас есть два варианта. Вы можете просто установить свойство столбца для отображения в числовом формате после загрузки CSV. Просто щелкните правой кнопкой мыши на ячейке и выберите Format Cell... Оттуда просто выберите Number в списке. Это второй пункт. Закройте, и это должно выглядеть хорошо.

Если вам нужно импортировать файл в Excel уже правильно, то вам нужно будет обработать файл самостоятельно. Вы можете сделать это на любом языке программирования. Просто читайте в полях и выводите их как хотите.

Вот пример VBScript:

' The columns begin at index 0, this array should include indexes for each column which should be treated literally.
' The script will add a = before these columns if it doesn't already exist.

' If you want you could add the ability to set this at the command line to make this more flexible.
literalColumns=Array(1)

'----------------------------------------------------------
' Nothing else should need to be changed.

IsOK=True
FileNotFound=False
CSVFileName=""
OutputFileName="output.csv" ' This is the default output file to use when none is given via the command line.

If WScript.Arguments.Count = 1 Or WScript.Arguments.Count = 2 Then
    CSVFileName = WScript.Arguments.Item(0)
    If WScript.Arguments.Count = 2 Then
        OutputFileName = WScript.Arguments.Item(1)
    End If
Else
    CSVFileName = InputBox("Enter a CSV file name to process:", "CSV Input File")
    If Len(CSVFileName) < 1 Then
        IsOK=False
        FileNotFound = True
    End If
End If

If IsOK Then
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    If objFSO.FileExists(CSVFileName) Then
        ProcCSV CSVFileName, OutputFileName
    Else
        IsOK = False
        FileNotFound = True
    End If
End If

If IsOK = False Then
    msg="Usage: PrepCSV.vbs CSVFileName [OutputFileName]"
    If FileNotFound Then
        msg = msg & vbCrLf & vbCrLf &"File Not Found."
    End If
    Wscript.Echo msg
    Wscript.Quit
End If

Sub ProcCSV(InFileName, OutFileName)
    ReDim ToInsert(0)
    Set FS = CreateObject("Scripting.FileSystemObject")
    Set InFile = FS.OpenTextFile(InFileName, 1, False, -2)
    Set OutFile = objFSO.CreateTextFile(OutFileName)
    Set Regex = CreateObject("VBScript.RegExp")
    Regex.Pattern = """[^""]*""|[^,]*"
    Regex.Global = True
    Do While Not InFile.AtEndOfStream
        ReDim ToInsert(0)
        CSVLine = InFile.ReadLine
        For Each Match In Regex.Execute(CSVLine)
            If Match.Length > 0 Then
                ColDX = UBound(ToInsert)
                ReDim Preserve ToInsert(ColDX + 1)
                If InArray(ColDX, literalColumns) And Left(Match.Value, 1) <> "=" Then
                    ToInsert(ColDX) = "=" & Match.Value
                Else
                    ToInsert(ColDX) = Match.Value
                End If
            End If
        Next
        CSVLine = Join(ToInsert, ",")
        OutFile.Write Left(CSVLine, Len(CSVLine) - 1) & vbCrLf
    Loop
    InFile.Close
    OutFile.Close
End Sub

Function InArray(item, arr)
    For i=0 To UBound(arr)
        If arr(i) = item Then
            InArray=True
            Exit Function
        End If
    Next
    InArray=False
End Function

Чтобы использовать это, просто сохраните приведенный выше текст в файл с именем PrepCSV.vbs . Затем вы можете щелкнуть по нему и ввести имя файла для обработки или вызвать его из командной строки, например:

PrepCSV.vbs inputfile.csv outputfile.csv