Выровнять начало вторичной оси с первичным

Question

Я заинтересован в выравнивании моей вторичной оси так, чтобы она точно совпадала с моей первичной осью.

Чтобы быть более понятным, я хочу, чтобы источники располагались в 0 в одном и том же месте, каждый из которых сохраняет свой относительный масштаб.

Я бы предпочел, чтобы это было либо решение VBA, либо сведение к минимуму ручной работы.

Answer 1

Я использовал эту ссылку: http://peltiertech.com/Excel/Charts/AlignXon2Ys.html

' Helper Macros
Sub AlignY_PrimaryMinimum()
  AlignY 1
End Sub

Sub AlignY_PrimaryMaximum()
  AlignY 2
End Sub

Sub AlignY_SecondaryMinimum()
  AlignY 3
End Sub

Sub AlignY_SecondaryMaximum()
  AlignY 4
End Sub

' The Main Event
Sub AlignY(FreeParam As Integer)
  '' FreeParam: AXIS ALLOWED TO VARY
  '' 1: Y1 (PRI) MIN
  '' 2: Y1 (PRI) MAX
  '' 3: Y2 (SEC) MIN
  '' 4: Y2 (SEC) MAX

  Dim Y1min As Double
  Dim Y1max As Double
  Dim Y2min As Double
  Dim Y2max As Double

  With ActiveChart
    With .Axes(2, 1)
      Y1min = .MinimumScale
      Y1max = .MaximumScale
      .MinimumScaleIsAuto = False
      .MaximumScaleIsAuto = False
    End With
    With .Axes(2, 2)
      Y2min = .MinimumScale
      Y2max = .MaximumScale
      .MinimumScaleIsAuto = False
      .MaximumScaleIsAuto = False
    End With
    Select Case FreeParam
      Case 1
        If Y2max <> 0 Then _
          .Axes(2, 1).MinimumScale = Y2min * Y1max / Y2max
      Case 2
        If Y2min <> 0 Then _
          .Axes(2, 1).MaximumScale = Y1min * Y2max / Y2min
      Case 3
        If Y1max <> 0 Then _
          .Axes(2, 2).MinimumScale = Y1min * Y2max / Y1max
      Case 4
        If Y1min <> 0 Then _
          .Axes(2, 2).MaximumScale = Y2min * Y1max / Y1min
    End Select
  End With
End Sub

Answer 2

Будет ли это работать?

Sub RescaleSecondaryAxis()

    Dim PriMax, PriMin
    Dim SecMax, SecMin

    ActiveSheet.ChartObjects("myChart").Activate
    ActiveChart.Axes(xlValue, xlPrimary).Select

    PriMax = ActiveChart.Axes(xlValue, xlPrimary).MaximumScale
    PriMin = ActiveChart.Axes(xlValue, xlPrimary).MinimumScale

    SecMax = PriMax 
    SecMin = PriMin 

    ActiveChart.Axes(xlValue, xlSecondary).MaximumScale = SecMax
    ActiveChart.Axes(xlValue, xlSecondary).MinimumScale = SecMin

End Sub