Тест на отключение Wi-Fi

Question

Я получил ноутбук от кого-то, кто видел, как он отключался несколько раз в день от определенной сети Wi-Fi.

Чтобы устранить эту проблему, я сначала хотел бы определить, возникает ли проблема здесь, в нашей офисной сети.

Если бы это происходило каждые 10 минут, я бы просто использовал компьютер и посмотрел, испытываю ли я отключение, но с ожидаемой частотой раз в несколько часов это не очень практично, так как я могу просто пропустить его в течение длительного времени.

Я искал решение для этого, но я нашел только предложенные подходы, чтобы решить эту проблему, без надлежащего способа проверить, действительно ли проблема возникает.

Отсюда мой вопрос:

Каков практический способ проверить наличие Wi-Fi-соединений?

Answer 1

Для отключения вы можете использовать что-то вроде этого ответа.

Вы можете запустить это на другом компьютере по checklink <ip_of_laptop> .

Вы также можете запустить это на ноутбуке с помощью checklink <your_network_server> .

checklink.cmd:

@setlocal enableextensions enabledelayedexpansion
@echo off
set ipaddr=%1
set oldstate=neither
:loop
set state=up
ping -n 1 !ipaddr! >nul: 2>nul:
if not !errorlevel!==0 set state=down
if not !state!==!oldstate! (
    echo.%time% Link is !state!
    set oldstate=!state!
)
ping -n 2 127.0.0.1 >nul: 2>nul:
goto :loop
endlocal

Он покажет вам, когда ноутбук находится в автономном режиме, а также когда он снова появится в сети.
Запустите его на полдня, и вы увидите, есть ли у ноутбука проблемы с отключением.

(ping -n 2 127.0.0.1 - это пауза, чтобы не постоянно бомбить ноутбук пингами)

Answer 2

Я бы сказал, что если пропускная способность не является проблемой, вы можете скачать очень большой файл. если соединение обрывается, то загрузка будет остановлена, когда вы вернетесь.

Другая вещь, которую вы можете сделать, это получить себе монитор полосы пропускания, который отслеживает сетевой трафик, так что вы сможете увидеть снижение скорости и отключение на графиках, которые они дают.

Надеюсь это поможет.