Как отключить всплывающую подсказку на вкладках

Question

Есть ли способ отключить всплывающие подсказки на вкладках в Chrome?

Они могут раздражать и отвлекать всякий раз, когда указатель мыши оказывается на вкладке.

Answer 1

Вы не можете отключить эти подсказки в Chrome.

Через:http://productforums.google.com/forum/#!topic/chrome/ygoNhTB5K1Y https://groups.google.com/forum/#!topic/chromebook-central/gxAnZM-2tpM http://forums. mozillazine.org/viewtopic.php?f=7&t=1562905

Answer 2

Я не мог придумать идею о том, что программа переместит курсор для вас из головы, поэтому я бросил ее вместе.

Ниже приведен сценарий AutoHotkey (который может быть скомпилирован в автономный исполняемый файл, если это необходимо), который определяет, когда курсор мыши некоторое время оставался незанятым в верхней части окна Chrome, и, если это так, перемещает его в правый нижний угол экран.

Он работает должным образом и предотвращает всплывающие подсказки, но из-за смещенного времени (запуска подпрограммы и обратного отсчета всплывающей подсказки) иногда всплывающая подсказка всплывает на долю секунды перед перемещением курсора. Это можно уменьшить, уменьшив таймер (переменная tip ).

Я также думаю об улучшении сценария путем обработки таймера вручную вместо использования таймера AutoHotkey. Таким образом, он может отсчитывать от последнего раза, когда мышь перемещали или нажимали кнопку, а не только каждые x секунд, независимо.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   MoveIdleMouse.ahk
;
; Prevents tooltips from being annoying in Chrome by detecting
; when the mouse is idle while near the top of a Chrome window
; and then moving it to the bottom-right corner of the screen.
;
; https://superuser.com/questions/393738/
;
;   (cl) 2013- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#SingleInstance force
#Persistent

; Read the tooltip delay from the registry (this is the amount of time the
; cursor has to hover over something in order to trigger the tooltip)
RegRead, tip, HKCU, Control Panel\Mouse, MouseHoverTime

; Divide it by two to accommodate staggared timing. Adjust as desired.
;tip:=tip/2

; Set specified subroutine to run every so often (before tooltip triggered)
SetTimer, CheckCursor, %tip%

; Get the current mouse cursor position to compare to during first interval
MouseGetPos, x1, y1
return

; This subroutine checks the current cursor position and moves if idle
CheckCursor:
  ; First check if the cursor is over a Chrome window; ignore if not
  IfWinNotActive, ahk_class Chrome_WidgetWin_0
    return

  ; Next, check if any buttons are pressed and ignore if so
  if (GetKeyState("LButton") or GetKeyState("RButton") or GetKeyState("MButton")
      or GetKeyState("XButton1") or GetKeyState("XButton2"))
    return

  ; Get the current mouse position and check if it is both unchanged, and
  ; near the top of Chrome (position is relative to window by default)
  MouseGetPos, x2, y2
  If (((x1 = x2) and (y1 = y2))  and  ((y2 >= 0) and (y2 <= 27)))
  {
    ; Move the cursor to the bottom-right corner of the screen immediately
    ; You can adjust destination position as desired
    MouseMove, A_ScreenWidth+3, A_ScreenHeight+3, 0
  }
  else {
    ; Update current cursor position to compare to during the next interval
    x1 := x2
    y1 := y2
  }
  return