Экспорт таблицы Office Excel в CSV с помощью макроса

Question

Я использую таблицы Excel в Excel 2010. Я хотел бы быстро экспортировать содержимое этих таблиц в * .csv.

Мой текущий рабочий процесс:1. Выберите стол вручную 2. Скопируйте содержимое в новую рабочую книгу. 3. Сохраните книгу как файл * .csv

Желаемый рабочий процесс:1. Выберите стол вручную 2. Запустите макрос, который записывает в предварительно определенное имя файла

Поскольку таблицы имеют уникальные имена (например, CurrentDataTable), существует ли функция, которая берет имя таблицы, целевой файл и желаемый выходной формат и записывает выходной файл?

Answer 1

Нет встроенной команды или функции Excel, которая бы выполняла то, что вам нужно, но вы можете использовать VBA для ее программирования.

Следующий код может быть близок к тому, что вы ищете:

Sub ExportTable()

    Dim wb As Workbook, wbNew As Workbook
    Dim ws As Worksheet, wsNew As Worksheet
    Dim wbNewName As String


   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Set wbNew = Workbooks.Add

   With wbNew
       Set wsNew = wbNew.Sheets("Sheet1")
       wbNewName = ws.ListObjects(1).Name
       ws.ListObjects(1).Range.Copy
       wsNew.Range("A1").PasteSpecial Paste:=xlPasteAll
       .SaveAs Filename:=wb.Path & "\" & wbNewName & ".csv", _
             FileFormat:=xlCSVMSDOS, CreateBackup:=False
   End With

End Sub

Код предполагает, что у вас есть одна таблица на каждом листе. Он создает новую книгу, копирует таблицу в лист 1 этой книги и сохраняет книгу в виде файла CSV с тем же именем, что и таблица.

Answer 2

Вот моя версия ответа Чаффа для Excel 2013. Это также отключает модальные диалоги:

Sub ExportCSV()

   Dim wb As Workbook, wbNew As Workbook
   Dim ws As Worksheet, wsNew As Worksheet

   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Set wbNew = Workbooks.Add
   Application.DisplayAlerts = False
   With wbNew
       Set wsNew = wbNew.Sheets("Sheet1")
       ws.Rows.Copy
       wsNew.Paste
       .SaveAs Filename:=ws.name & ".csv", FileFormat:=xlCSV, CreateBackup:=True
       wsNew.Delete
   End With
   Windows(ws.name & ".csv").Activate
   ActiveWindow.Close
   Application.DisplayAlerts = True

End Sub

Answer 3

Мне нужно было сделать то же самое, но нужно было указать, какие таблицы нужно было экспортировать в виде файлов CSV. Я создал диапазон с именем «ExportTables», с VBA следующим образом:

Public Sub Export()
    Dim i       As Integer
    Dim iMax    As Integer
    Dim sTable  As String

    iMax = Range("ExportTables").Rows.Count

    For i = 1 To iMax
        sTable = Range("ExportTables").Cells(i, 1).Value
        Call ExportTable(sTable)
    Next i
End Sub

Public Sub ExportTable(tableName As String)
    Dim wkb         As Workbook
    Dim wkbNew      As Workbook
    Dim wks         As Worksheet
    Dim wksNew      As Worksheet

    Set wkb = ThisWorkbook

    Application.Goto Reference:=tableName
    Set wks = ActiveSheet

    Set wkbNew = Workbooks.Add
    Set wksNew = wkbNew.Sheets(1)

    wks.ListObjects(tableName).Range.Copy
    wksNew.Range("A1").PasteSpecial Paste:=xlPasteValues

    Application.DisplayAlerts = False

    wkbNew.SaveAs Filename:=wkb.Path & "\" & tableName & ".csv", _
        FileFormat:=xlCSV, CreateBackup:=False
    wkbNew.Close SaveChanges:=False

    Application.DisplayAlerts = True

    ' Release object variables.
    Set wkb = Nothing
    Set wkbNew = Nothing
    Set wks = Nothing
    Set wksNew = Nothing
End Sub