MS Word: выравнивание по центру только изображения в списке

Question

Я сделал нумерованный список в Word 2010. Каждая запись в списке также имеет изображение. Я хочу выровнять по центру все изображения, но когда я пытаюсь выровнять изображение по центру, текст выше также центрируется.

Как я могу по центру выравнивать изображения в списке без центрирования текста сверху и снизу.

Answer 1

Хорошо, вот что вы делаете:

1. Щелкните правой кнопкой мыши на изображении и выберите «Размер и положение ...»'
2. Выберите вкладку «Обтекание текстом»
3. Выберите «Верх и низ»
4. Выберите вкладку «Положение»
5. В разделе «Горизонтально» выберите «Выравнивание», а затем выберите «По центру» относительно «Столбец»

К сожалению, сделать это для нескольких изображений проблематично. Художник формата не будет работать. Кроме того, простое использование Macro Recorder вызывает проблемы при попытке выбрать изображение.

Таким образом, создание макроса VBA и привязка его к ключу, по-видимому, является единственным способом сделать этот суперэффективным. Вот два полезных сообщения на этот счет:

• https://groups.google.com/forum/?fromgroups=#!topic/microsoft.public.word.vba.general/j4ZaBiOYKDU
• https://stackoverflow.com/questions/9809475/insert-resize-and-relocate-image-using-a-microsoft-word-macro

Из первой из этих ссылок я протестировал следующий макрос VBA. Кажется, работает нормально!

Sub FormatMyPicture()  
   Dim myShape As Shape

   If Selection.InlineShapes.Count > 0 Then
       Set myShape = Selection.InlineShapes(1).ConvertToShape
   ElseIf Selection.ShapeRange.Count > 0 Then
       Set myShape = Selection.ShapeRange(1)
   Else
       MsgBox "Please select a picture first."
       Exit Sub
   End If

   With myShape
       .WrapFormat.Type = wdWrapTopBottom
       .WrapFormat.DistanceTop = InchesToPoints(0.2)
       .WrapFormat.DistanceBottom = InchesToPoints(0.2)
       .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
       .Left = wdShapeCenter
   End With
End Sub

Answer 2

Надеюсь, что это поможет кому-то особенному

Sub rezize_center_newline()

Dim i As Long
Dim shpIn As InlineShape, shp As Shape

With ActiveDocument
    For i = 1 To .InlineShapes.Count
        With .InlineShapes(i)
            .Height = InchesToPoints(4)
            .Width = InchesToPoints(5.32)
            .Range.InsertAfter Chr(13)
        End With
    Next i
    For Each shpIn In ActiveDocument.InlineShapes
        shpIn.Select
        Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    Next shpIn
    For Each shp In ActiveDocument.Shapes
        shp.Select
        Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    Next shp
End With
End Sub

Answer 3

Чтобы выровнять центр всего встроенного изображения в MS Word:

Шаг 1: Нажмите Alt+F11, чтобы открыть VBA Editor

Шаг 2: Перейти к Insert затем Module

Шаг 3. В редакторе VBA введите следующий фрагмент кода

Sub centerPictures()
  Dim shpIn As InlineShape, shp As Shape
  For Each shpIn In ActiveDocument.InlineShapes
    shpIn.Select
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
  Next shpIn
  For Each shp In ActiveDocument.Shapes
    shp.Select
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
  Next shp
End Sub

Шаг 4: Нажмите F5 или Run Sub чтобы применить это изменение