Модификатор прокрутки для мыши / трекбола в Windows

Question

У меня есть трекбол (в данном случае Logitech Trackman Marble, хотя это может относиться к любой мыши или указывающему устройству), где я хотел бы использовать одну из кнопок в качестве среднего щелчка, когда я нажимаю на нее, но для запуска прокрутки, когда я удерживайте его и переместите шар.

Я мог бы сделать это довольно легко в Linux, установив scroll-modifier в X config, но драйвер, который поставляется с трекболом (Logitech), позволяет только один или другой. Есть ли способ настроить это в Windows 8?

Answer 1

Кнопки управления X-Mouse должны работать. http://www.highrez.co.uk/downloads/XMouseButtonControl.htm Вам просто нужно установить одну из кнопок на "Изменить движение для прокрутки". То, как это работает с моей мышью, - я держу кнопку, затем, перемещая мышь, прокручивает страницу вместо перемещения указателя. Он должен работать так же, как для трекбола.

Answer 2

Мраморное колесо мыши

• Загрузите Мраморное колесо мыши (http://marble-mouse-scroll-wheel.software.informer.com/download)
• Игнорировать или отменить рекламу, только скачать marbleinst.exe
• После установки запустите его в режиме совместимости для Windows 7.
• Установите Back (Button4) в качестве кнопки прокрутки.

Мраморный свиток

Аналогичный исполняемый файл, другое расположение:

• Загрузите https://sites.google.com/site/marblescroll/download

Answer 3

Я только что получил мышь Logitech Marble, а также возникла проблема с прокруткой. Поэтому я сделал этот скрипт на AutoHotKey. Левая кнопка X позволяет выполнять прокрутку, а это означает, что, нажимая вниз, вы можете прокручивать мяч вертикально и горизонтально, а также перемещаться вперед и назад в браузере с помощью левой и правой кнопок. Правая кнопка X имеет то же действие, что и средняя кнопка.

Я на Windows 7.

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN