Word Macro - номер счета и имя файла с автоматическим увеличением при сохранении

Question

Мы разрабатываем шаблон счета для Word, который содержит номер счета в поле вверху страницы.

Мы бы хотели, чтобы номер счета автоматически увеличивался (начиная с последнего номера счета), и мы хотели бы, чтобы имя файла основывалось на номере счета.

Все они будут сохранены в одном каталоге.

Answer 1

 Sub GoGenInv()
    Selection.GoTo What:=wdGoToBookmark, Name:="BkMrk_InvNum"
    Selection.MoveRight Unit:=wdCharacter, Count:=10, Extend:=wdExtend
    Dim nInvNum As Variant
    nInvNum = Val(Selection.Text)
    nInvNum = nInvNum + 1
    Selection.Text = nInvNum
    Selection.GoTo What:=wdGoToBookmark, Name:="BkMrk_InvNum"
End Sub

Answer 2

Я нашел это, которое, я думаю, решит проблему:

Используйте макрос Autonew, чтобы добавить порядковый номер в документ и сохранить его под этим номером.

В шаблоне, из которого вы создаете документ, вставьте закладку с именем Order в место, где вы хотите, чтобы появился порядковый номер, и создайте макрос AutoNew в шаблоне следующим образом:

Sub AutoNew()

Order = System.PrivateProfileString("C:\Settings.Txt", _
        "MacroSettings", "Order")

If Order = "" Then
    Order = 1
Else
    Order = Order + 1
End If

System.PrivateProfileString("C:\Settings.txt", "MacroSettings", _
        "Order") = Order

ActiveDocument.Bookmarks("Order").Range.InsertBefore Format(Order, "00#")
ActiveDocument.SaveAs FileName:="path" & Format(Order, "00#")

End Sub

Если вам не нужно отображать номер в документе, а просто сохранить его с последовательным номером, нет необходимости создавать закладку в шаблоне, а затем следует удалить вторую последнюю строку кода.