Excel: подсчет количества значений MAX в диапазоне

Question

Я использую Excel 2003 (версия ограничена из-за корпоративной политики) для ведения таблицы результатов:

     A       B     C     D
1  Round | Rita | Sue | Bob
   ------+------+-----+-----
2    1   |   5  |  3  |  4
3    2   |   2  |  2  |  5
4    3   |   3  |  1  |  3

Я хочу, чтобы у каждого человека было общее количество выигрышных раундов, а галстук присуждается обоим. Таким образом, общая строка должна выглядеть примерно так:

   -------+------+-----+-----
 5  Total |   2  |  0  |  2

Возможно ли это в одной формуле для итога?

Я пробовал комбинации CountIf и Max но не могу получить желаемый результат.

Мое единственное другое решение - это иметь отдельный набор столбцов оценок: например, IF(B2=MAX(B2:D2),1,0) для каждого раунда, а затем суммировать их для каждого человека.

РЕДАКТИРОВАТЬ: Чтобы было ясно, у меня есть решение, которое включает в себя добавление дополнительных столбцов. Я прошу решения, позволяющие добавить формулу (е) в каждый существующий столбец для расчета итогов без добавления дополнительных столбцов.

Answer 1

Попробуйте эту формулу в B5, скопированную в D5, она даст вам итоги для Rita, Sue and Bob too

=SUMPRODUCT((SUBTOTAL(4,OFFSET($B$2:$D$4,ROW($B$2:$D$4)-ROW(B$2),0,1))=B2:B4)+0)

Это решение может быть легко расширено до больших диапазонов, то есть с большим количеством строк или столбцов .....

OFFSET выдержек каждую строку в качестве отдельного диапазона и SUBTOTAL с первым аргументом 4 находит MAX каждого диапазона .....]

Answer 2

Добавьте новый столбец рядом с BOB с формулой ``

=MAX(B2,C2,D2)

Для ячейки Total поставьте следующее

=SUM(IF(B2=$E2,1,0),IF(B3=$E3,1,0),IF(B4=$E4,1,0))

ПРИМЕЧАНИЕ: все формулы основаны на предположении, что ячейка Round является A1
(также я попробовал это на Office 2010, поэтому не знаю, если точные функции будут доступны в 2003 году

РЕДАКТИРОВАТЬ
Если вам не нужен дополнительный столбец, вы можете объединить две формулы таким образом

=SUM(IF(B2=MAX(B2,C2,D2),1,0),IF(B3=MAX(B3,C3,D3),1,0), and so on )