Mac OS: Automator-скрипт для сохранения писем в автоматически сгенерированные папки

Question

Я смотрю в автоматизатор и мне нужно, чтобы помочь мне со следующей простой задачей:

Мне нужно иметь вложения ряда сообщений, которые сортируются в папке в Mail, загружаются и сохраняются в папки, имена которых указаны по адресу электронной почты отправителя.

Если возможно, я бы хотел, чтобы стенограмма письма сохранялась вместе с вложениями (это можно сделать, распечатав PDF-файл?)

Я никогда не использовал automator, но в настоящее время я настроил действие "Получить указанные элементы почты", которое подключено к нужной папке в почте, и я настроил "Получить вложения из почтового сообщения", но мне нужно узнайте, как назвать папки по именам отправителей и как сохранить их в этих папках.

Answer 1

Вероятно, вам лучше использовать Applescript или что-то подобное, что позволит вам лучше контролировать свойства отдельных сообщений.

РЕДАКТИРОВАТЬ: потребовалось гораздо больше проб и ошибок, чем я думал, но вы должны быть в состоянии выбрать пакет сообщений, запустить этот сценарий и заставить его выплевывать папки для каждого отправителя в любую папку, которую вы указали в начале. Это не делает регистрации, но, возможно, этого достаточно, чтобы вы начали.

Также отмечу, что команда save [attachment] в [attachmentPath] не работает в Lion на 10.7 и 10.7.1 (я думаю, что оба), но, похоже, исправлена в 10.7.2, основываясь на том, что я уже делал. чтение. Так что YMMV, если вы не работаете 10.7.2.

РЕДАКТИРОВАТЬ еще раз: больше редакций ... теперь мы не будем создавать папки для сообщений, которые не имеют вложений ...

tell application "Mail"
    set selectedMessages to selection

    set destinationFolder to choose folder with prompt "Pick a Destination"

    repeat with currentMessage in selectedMessages
        repeat 1 times
            set msgSender to sender of currentMessage
            set msgAttachments to mail attachments of currentMessage
            if (msgAttachments is equal to {}) then
                exit repeat
            end if
            tell application "Finder"
                if not (exists folder msgSender of destinationFolder) then
                    set senderFolder to (make new folder at destinationFolder with properties {name:msgSender})
                else
                    set senderFolder to (folder msgSender of destinationFolder)
                end if
            end tell

            repeat with currentAttachment in msgAttachments
                if (downloaded of currentAttachment is true) then
                    set currentAttachmentPath to (senderFolder as string) & (name of currentAttachment)
                    save currentAttachment in currentAttachmentPath
                end if
            end repeat
        end repeat
    end repeat

end tell