Vim: Показать индекс вкладок в строке

Question

Допустим , я открыл file1.txt , file2.txt , file3a.txt и file3b.txt , что табуляция (вещь сверху) выглядит следующим образом:

file1.txt  file2.txt  2 file3a.txt

(Обратите внимание, что file3b.txt. Отсутствует, потому что он отображается в разделении, на той же вкладке, что и file3a.txt)

Чтобы быстрее перемещаться между вкладками (с <Number>gt), я бы хотел, чтобы каждая вкладка отображала свой индекс вдоль имени файла. Вот так:

1:<file1.txt>  2:<file2.txt>  3:<2 file3a.txt>

Форматирование (в частности, угловые скобки) не является обязательным; Я просто хочу, чтобы там появился индекс (1: 2: и т.д.).

Никаких подсказок :h tab-page-commands или Google вообще.

Answer 1

положи это в свой vimrc

" Rename tabs to show tab number.
" (Based on http://stackoverflow.com/questions/5927952/whats-implementation-of-vims-default-tabline-function)
if exists("+showtabline")
    function! MyTabLine()
        let s = ''
        let wn = ''
        let t = tabpagenr()
        let i = 1
        while i <= tabpagenr('$')
            let buflist = tabpagebuflist(i)
            let winnr = tabpagewinnr(i)
            let s .= '%' . i . 'T'
            let s .= (i == t ? '%1*' : '%2*')
            let s .= ' '
            let wn = tabpagewinnr(i,'$')

            let s .= '%#TabNum#'
            let s .= i
            " let s .= '%*'
            let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
            let bufnr = buflist[winnr - 1]
            let file = bufname(bufnr)
            let buftype = getbufvar(bufnr, 'buftype')
            if buftype == 'nofile'
                if file =~ '\/.'
                    let file = substitute(file, '.*\/\ze.', '', '')
                endif
            else
                let file = fnamemodify(file, ':p:t')
            endif
            if file == ''
                let file = '[No Name]'
            endif
            let s .= ' ' . file . ' '
            let i = i + 1
        endwhile
        let s .= '%T%#TabLineFill#%='
        let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
        return s
    endfunction
    set stal=2
    set tabline=%!MyTabLine()
    set showtabline=1
    highlight link TabNum Special
endif

Answer 2

На странице wikia вы можете найти по крайней мере два (те, которые я тестировал), которые дают вам индексы вкладок, и одно из них выдает количество окон внутри каждого буфера, которые имеют правки.

Вот результат моих модификаций для той, которая производит количество отредактированных буферов, изменение, которое я сделал, должно было сделать значение подсветки счетчика совместимым с остальной частью вкладки:

set tabline=%!MyTabLine()  " custom tab pages line
function MyTabLine()
        let s = '' " complete tabline goes here
        " loop through each tab page
        for t in range(tabpagenr('$'))
                " set highlight
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " set the tab page number (for mouse clicks)
                let s .= '%' . (t + 1) . 'T'
                let s .= ' '
                " set page number string
                let s .= t + 1 . ' '
                " get buffer names and statuses
                let n = ''      "temp string for buffer names while we loop and check buftype
                let m = 0       " &modified counter
                let bc = len(tabpagebuflist(t + 1))     "counter to avoid last ' '
                " loop through each buffer in a tab
                for b in tabpagebuflist(t + 1)
                        " buffer types: quickfix gets a [Q], help gets [H]{base fname}
                        " others get 1dir/2dir/3dir/fname shortened to 1/2/3/fname
                        if getbufvar( b, "&buftype" ) == 'help'
                                let n .= '[H]' . fnamemodify( bufname(b), ':t:s/.txt$//' )
                        elseif getbufvar( b, "&buftype" ) == 'quickfix'
                                let n .= '[Q]'
                        else
                                let n .= pathshorten(bufname(b))
                        endif
                        " check and ++ tab's &modified count
                        if getbufvar( b, "&modified" )
                                let m += 1
                        endif
                        " no final ' ' added...formatting looks better done later
                        if bc > 1
                                let n .= ' '
                        endif
                        let bc -= 1
                endfor
                " add modified label [n+] where n pages in tab are modified
                if m > 0
                        let s .= '[' . m . '+]'
                endif
                " select the highlighting for the buffer names
                " my default highlighting only underlines the active tab
                " buffer names.
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " add buffer names
                if n == ''
                        let s.= '[New]'
                else
                        let s .= n
                endif
                " switch to no underlining and add final space to buffer list
                let s .= ' '
        endfor
        " after the last tab fill with TabLineFill and reset tab page nr
        let s .= '%#TabLineFill#%T'
        " right-align the label to close the current tab page
        if tabpagenr('$') > 1
                let s .= '%=%#TabLineFill#%999Xclose'
        endif
        return s
endfunction

Answer 3

Плагин tabline - это плагин vim, который реализует запрошенную функциональность и не разрушает ваш vimrc. Просто установите и перезапустите vim.

Установить:

cd /usr/share/vim/vimfiles/plugin/
wget https://raw.githubusercontent.com/mkitt/tabline.vim/master/plugin/tabline.vim

или используйте менеджер плагинов.

Answer 4

Для Vim на основе графического интерфейса (Gvim для Linux, MacVim для Mac и т.д.), Поместите это в ваш .gvimrc:

set guitablabel=%N:%M%t " Show tab numbers

Несколько советов по фактическому использованию отображаемых чисел:

• Ngt переключится на вкладку N Например, 3gt переходит на вкладку 3.
• :tabm2 перемещает текущую вкладку, чтобы появиться после вкладки 2.
  • Чтобы переместить эту вкладку на первую позицию, используйте :tabm0
  • Чтобы переместить эту вкладку на последнюю позицию, просто используйте :tabm

Answer 5

Вам нужно посмотреть на:

:help 'tabline'
:help setting-tabline

И если у вас есть "е" в настройках "guioptions":

:help 'guitablabel'