Интеграция iTerm2 и tmux

Question

Я хотел бы добиться следующего поведения:

Когда я запускаю iTerm2, если запущен сеанс tmux, подключайтесь к нему. Если сеанс tmux не запущен, создайте его и подключитесь к нему.

Любые указатели очень ценятся!

Answer 1

Я использую этот скрипт, который exec всякий раз, когда моя оболочка запускается как оболочка входа в систему. Возможно, вы захотите немного отредактировать это ...

#/usr/bin/env zsh

local tmux=$1
local sname
local ssh

[[ -z "$tmux" ]] && tmux=tmux

# export COLORTERM to fix some programs
case "$TERM" in
  *256color)
    export COLORTERM="$TERM" ;;
esac

# build a fancy session name
[[ ! -z "$SSH_CLIENT" ]] && ssh="/$SSH_CLIENT"
sname=$(print -P "%D{%Y-%m-%d-%H-%M-%S}/%n/%y$ssh")

# make sure session 0 exists  
$tmux has-session -t 0 2>/dev/null || $tmux new-session -d -s 0

# create our own mirroring session
$tmux new-session -d -s "$sname" -t 0

# this doesn't return until the session is closed or detached
$tmux attach-session -t "$sname"

# kill the mirroring session if it's not dead already 
$tmux has-session -t "$sname" 2>/dev/null && $tmux kill-session -t "$sname"

# return to prompt outside of tmux if special file is present 
if [[ -f "$TMUX_LEAVE_SHELL_FILE" ]]; then
  rm "$TMUX_LEAVE_SHELL_FILE"
  exec zsh -i
fi

Соответствующий раздел в моем .zshrc

# drop into tmux if this is a login shell and we're not in tmux already
if (which tmux >/dev/null) && [[ -o login ]] &&  [[ -z "$TMUX" ]] && [[ -f ~/etc/script/tmux-login ]]; then
  exec zsh "$HOME/etc/script/tmux-login" $(which tmux)
fi

# handy command to detach tmux but keep the shell running (kind-of)
case $TERM in
  screen)
    alias detach="touch $TMUX_LEAVE_SHELL_FILE && tmux detach" ;;
esac