Могу ли я в OSX запускать, позиционировать и масштабировать приложение, используя applecript /automator?

Question

Я ищу, чтобы автоматизировать запуск моего рабочего пространства. Я использую несколько приложений, аккуратно расположенных на двух мониторах, и я хотел бы иметь возможность запускать предпочитаемые макеты одним щелчком мыши

Я знаю, как запускать несколько приложений с помощью сценария автоматизации, теперь мне просто нужно иметь возможность размещать приложения на своих экранах.

Большое спасибо.

Answer 1

Это, хотя и возможно, может быть слишком сложным для сценария. Вот частичный пример скрипта, который восстанавливает Firefox и Itunes Windows (адаптировано из скрипта, найденного здесь.)

property numFFWindows : 0
property FFPos : {}
property FFSize : {}
property iTunesPos : {}
property iTunesSize : {}

display dialog "Set Window Position or Save Window Position?" buttons {"Restore", "Save"} default button "Restore"
set theResult to result

tell application "System Events"
    if (button returned of theResult is "Restore") then
        -- Restore Settings
        if (numFFWindows > 0) then
            tell process "Firefox"
                repeat with i from 1 to numFFWindows
                    set position of window i to (item i of FFPos)
                    set size of window i to (item i of FFSize)
                end repeat
            end tell
        end if
        if (iTunesPos is not {0, 0}) then
            tell process "iTunes"
                set position of window 1 to iTunesPos
                set size of window 1 to iTunesSize
            end tell
        end if
    else
        -- Save Settings
        tell process "Firefox"
            set numFFWindows to count windows
            set FFPos to {}
            set FFSize to {}
            repeat with i from 1 to numFFWindows
                set end of FFPos to (position of window i)
                set end of FFSize to (size of window i)
            end repeat
        end tell
        tell process "iTunes"
            set iTunesPos to position of window 1
            set iTunesSize to size of window 1
        end tell
    end if
end tell

Я предлагаю вам взглянуть на эту утилиту для большей гибкости:

http://cordlessdog.com/stay/

Answer 2

Вот еще один пример использования Applescript:

tell application "Finder"
    set {0, 0, dtw, dth} to bounds of window of desktop
end tell

tell application "Finder"
    reopen
    activate
    try
        set bounds of window 1 to {0, 22, dtw / 2, dth / 2}
    end try
end tell

tell application "Safari"
    reopen
    activate
    try
        set bounds of window 1 to {0, 22, dtw, dth}
    end try
end tell

tell application "Terminal"
    reopen
    activate
    try
        set position of window 1 to {0, 22}
        set size of window 1 to {dtw / 2, dth - 22}
    end try
end tell

tell application "TextEdit"
    reopen
    activate
    try
        set bounds of window 1 to {dtw / 2, 22, dtw, dth}
    end try
end tell

Для работы с несколькими мониторами требуется слишком много волшебства.

У SizeUp есть отдельные действия для перемещения окна к следующему монитору и установки границ для окон.