Макинтош Автоматический выход из определенных программ после неактивности системы

Question

Проблема: Такие программы, как «Вещи» и «Вместе», не любят, когда их открывают в двух местах, поэтому, хотя Dropbox отлично подходит для некоторых вещей, он менее чем идеален для них. Потеря данных может произойти. Таким образом, использование их на настольном компьютере / ноутбуке является проблемой, и не забыть выйти из них оказалось непоследовательно.

Желаемое решение: платное приложение (оно обязательно должно существовать? Должно быть больше, чем я, который хочет этого), к которому я могу добавить определенные программы и который автоматически завершает их после x минут работы системы - не той программы - бездействия. или Яблочный скрипт с некоторыми пояснениями по использованию. Я в недоумении с яблочным скриптом и автоматом. Я попытался найти способ привязать это к запуску заставки, но ничего, что я пробовал, не сработало.

Супер бонусные баллы: чтобы приложение могло выйти из выбранных программ в режиме сна.

Я знаю, что могу получить доступ к рабочему столу с ноутбука, но я бы предпочел более автоматизированное решение, если оно существует. Я посмотрел, но если он там, я не могу его найти.

Любые идеи будут очень приветствоваться. Спасибо!

Answer 1

Однажды я использовал скрипт для обработки этого:

(*
Applescript Application to Auto Quit Things after certain period of system idle
http://culturedcode.com/forums/read.php?7,30174,30597
*)
(*
To make this runable, save as application.
To not show in Dock, set LSBackgroundOnly in Info.plist of created app bundle, or other ways in http://groups.google.com/group/macenterprise/browse_thread/thread/be7db35451e1dc70
*)

global quit_after, check_every

set quit_after to 900
set check_every to 100

(*
display dialog "Check is performed every " & check_every & " seconds. Things will be quit after " & quit_after & " seconds of system inactivity."
*)

on reopen
    display dialog "Check is performed every " & check_every & " seconds. Things will be quit after " & quit_after & " seconds of system inactivity."
end reopen

on idle
    set idletime to do shell script "echo $((`ioreg -c IOHIDSystem | sed -e '/HIDIdleTime/ !{ d' -e 't' -e '}' -e 's/.* = //g' -e 'q'` / 1000000000))"
    if (idletime as integer) > quit_after then
        tell application "System Events"
            if ((name of processes) contains "Things") then
                tell application "Things" to quit
            end if
        end tell
    end if
    return check_every
end idle

Вы можете запустить его с помощью редактора AppleScript, чтобы создать приложение, а затем запустить его автоматически, установив параметры Login Items в систему в настройках системы Account . Пожалуйста, следуйте веб-ссылкам в кодах для более подробной информации.