Есть ли настройка, чтобы перестать предупреждать меня в пустой теме?

Question

Возможный дубликат:
Как заставить Outlook 2010 не предупреждать о пустой теме?

Кто-то спросил это, но я так и не увидел ответа:

Есть ли настройка для остановки, чтобы предупредить меня в пустой теме?

Answer 1

Обновление: На самом деле, по этому вопросу и "кто-то спросил это" я искал дубликаты:

Как сделать так, чтобы Outlook 2010 не выводил меня на пустую тему?

Это действительно отвечает на вопрос:

Option Explicit

'=========================================================================
' Prevents Outlook® 2010 to display a no-subject warning message
' (c) Peter Marchert - http://www.outlook-stuff.com
' 2010-07-15 Version 1.0.0
' 2010-07-19 Version 1.0.1
'=========================================================================

Private WithEvents colInspectors As Outlook.Inspectors

Private Sub Application_Startup()

    '---------------------------------------------------------------------
    ' Set a reference to all forms
    '---------------------------------------------------------------------
    Set colInspectors = Outlook.Inspectors

End Sub

Private Sub colInspectors_NewInspector(ByVal Inspector As Inspector)

    '---------------------------------------------------------------------
    ' This code is running if a form (e. g. an e-mail) will be opened
    '---------------------------------------------------------------------

    Dim objItem As Object

    '---------------------------------------------------------------------
    ' Skip errors
    '---------------------------------------------------------------------
    On Error GoTo ExitProc

    '---------------------------------------------------------------------
    ' Set a reference to the open item
    '---------------------------------------------------------------------
    Set objItem = Inspector.CurrentItem

    '---------------------------------------------------------------------
    ' A new item does not have a received time
    '---------------------------------------------------------------------
    If Year(objItem.ReceivedTime) = 4501 Then

        '-----------------------------------------------------------------
        ' Check if the subject is empty if an e-mail was created by a
        ' template with predefined subject.
        '-----------------------------------------------------------------
        If objItem.Subject = "" Then objItem.Subject = " "

    End If

    ExitProc:

    '---------------------------------------------------------------------
    ' Delete the reference to the form and to the item
    '---------------------------------------------------------------------
    Set objItem = Nothing
    Set Inspector = Nothing

End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)

    On Error Resume Next

    '---------------------------------------------------------------------
    ' If the blank still exists it will now be removed (Outlook®
    ' will this not recognize)
    '---------------------------------------------------------------------
    Item.Subject = Trim(Item.Subject)

End Sub

Private Sub Application_Quit()

    '---------------------------------------------------------------------
    ' Delete the reference to the forms
    '---------------------------------------------------------------------
    Set colInspectors = Nothing

End Sub

---

Старый ответ, для ссылки на объяснение выбора Microsoft:

Зачем кому-то отправлять письмо с пустой строкой темы? Вы отправляете письмо с намерением, и тема должна подвести итог. Если оставить строку темы пустой, это повысит уровень доверия к спаму, и ваша почта может рассматриваться как нежелательная.

Outlook был спроектирован как корпоративный или корпоративный почтовый клиент, а не специально для личного / домашнего использования. Если вы получаете много писем, то легче просмотреть строки темы, чем тела содержимого, чтобы определить, какое действие необходимо предпринять для каждого письма ...

Примечательно: многие пользователи пострадали от отправки писем без строки темы, поэтому они попросили Microsoft внедрить это поведение в Outlook 2010, вы можете запросить параметр, чтобы изменить это, чтобы они могли реализовать его для следующего пакета обновления. Попробуйте обслуживание клиентов Microsoft ...