Как выбрать несколько строк на основе нескольких условий, используя функцию IF в Excel

Question

Чтобы упростить задачу, сначала посмотрите на изображение ниже

Я пытаюсь получить камеру под Which Event? (H2 ячейка), чтобы сказать, какие события они приглашены.

• Предположим, что человек приглашен только в Санджи, Свадьба и Прием, тогда я хочу, чтобы формула просто показывала Санджи, Свадьба и Прием(в ячейке H2), только если значение> = 1
• Если для Весваара и Санджи значение равно 0, а для Свадьбы и Приема > = 1, то я хочу, чтобы оно показывало только Свадьбу и Прием.
• Если значение равно 0 на Vesvaar, Sanji, Reception, но> = 1 на Wedding, то я хочу, чтобы оно показывало только Wedding.

Надеюсь, у меня есть смысл?

Я пытался использовать следующую формулу:

=IF((AND(D2>0,E2>0,F2>0,G2>0)),*All*,*Sanji, Wedding & Reception*)

Где, если я поставлю 1 на Vesvaar, Sanji, Wedding, Reception, ячейка H2 изменится на Все события. Но если значение равно 0 на Vesvaar, Sanji, Reception, но> = 1 на Wedding, то это не сработает.

Я действительно надеюсь, что я понял, и что вы можете мне помочь?

Answer 1

ЕСЛИ у вас есть Office 365 Excel, вы можете использовать TEXTJOIN в качестве формулы массива:

=IF(COUNTIF(D2:G2,">0")=4,"All",TEXTJOIN(",",TRUE,IF(D2:G2>0,$D$1:$G$1,"")))

Это должно быть подтверждено Ctrl-Shift-Enter вместо Enter при выходе из режима редактирования.

Если нет, то вам нужно будет констатировать строку самостоятельно:

=IF(COUNTIF(D2:G2,">0")=4,"All",MID(IF(D2>0,","&$D$1,"")&IF(E2>0,","&$E$1,"")&IF(F2>0,","&$F$1,"")&IF(G2>0,","&$G$1,""),2,200))

Answer 2

Альтернативный способ - преобразовать список в двоичный файл и использовать VLOOKUP для поиска событий.

=VLOOKUP((B2 > 0)*8 + (C2 > 0)*4 +(D2 > 0)*2 + (E2 > 0)*1, $H$2:$I$17, 2, FALSE)

Часть cell > 0 создает логическое значение, которое будет преобразовано в 0 или 1 в арифметическом выражении. Столбцы слева направо представляют цифры от наиболее значимых к наименее значимым

Таблица поиска может храниться где угодно, в некоторых столбцах / строках или на другом листе, и затем вы также можете скрыть этот лист / строки / столбцы

Вот таблица соответствия для вышеупомянутого

Number  Events
0       None
1       Reception
2       Wedding
3       Wedding, Reception
4       Sanji
5       Sanji, Reception
6       Sanji, Wedding
7       Sanji, Wedding, Reception
8       Vesvaar
9       Vesvaar, Reception
10      Vesvaar, Wedding
11      Vesvaar, Wedding, Reception
12      Vesvaar, Sanji
13      Vesvaar, Sanji, Reception
14      Vesvaar, Sanji, Wedding
15      All