Добавление дисков в панель навигации проводника Windows

Question

Я хочу отображать диски C: и D: так же, как «Этот компьютер» отображается на панели навигации. Я знаю процесс, который мне нужно пройти (см. Этот ответ), но не знаю, в каком месте реестра я должен редактировать. Может кто-нибудь указать мне на это? Если возможно, я бы также хотел добавить определенную папку в D: в панель навигации.

Я пробовал решение, предоставленное tenforums, однако это не смогло добавить диски.

Answer 1

Спасибо Саймону Мурье и его ответу Прикрепить папку к панели навигации в проводнике Windows:

PinDiskD.bat. Запустите, чтобы закрепить диск D:\ где-то над This PC в навигационной панели File Explorer . Запустите с любым непустым параметром, чтобы удалить диск D:\ из панели, например PinDiskD.bat x (обратите внимание на метку :deleAll ниже).

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=d DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%}                                   /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%}                 /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

PinDiskC.bat. Закрепляет диск C:\ на панели. То же, что и PinDiskD.bat, за исключением четырех основных set команд:

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"
set "_name=c SystemDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"
…

D:\bat\PinCodePages.bat. Прикрепляет определенную локальную папку к панели. То же самое, что и PinDiskD.bat, за исключением четырех основных set команд (проверьте правильность _icon , _name , _guid и _target ):

set "_icon=%%SystemRoot%%\system32\shell32.dll,176" # any valid icon
set "_name=My Folder"                               # any valid name
set "_guid=ffffffff-ffff-ffff-0000-00000000c0de"    # a valid GUID (no braces)
set "_target=d:\Utils\CodePages\\"                  # any valid local path
…

Пример того, как это выглядит в Windows 10 после запуска всех вышеперечисленных скриптов: