Скопировать уникальные значения из двух столбцов в третий столбец

Question

У меня есть основной список заказов в электронной таблице.

Столбец А перечисляет все заказы. Столбец B перечисляет подмножество всех заказов. Если бы оба списка были небольшими, я мог бы сделать это вручную, но у меня есть сотни записей для просмотра.

Каков наилучший способ найти значения из столбца A, которых нет в столбце B, и поместить их в столбец C?

Визуально, я хочу создать столбец C следующим образом:

Column A       Column B       Column C
A1             A3             A1
A2             A5             A2
A3                            A4
A4
A5

Обратите внимание, что я не пытаюсь просто выделить уникальные значения в столбце A, но я хочу скопировать эти уникальные значения в новый столбец (C).

Answer 1

Пытаться:

=IFERROR(INDEX($A$1:$A$100,AGGREGATE(15,6,1/(1/(ISNA(MATCH($A$1:$A$100,$B$1:$B$100,0))*ROW($A$1:$A$100)*($A$1:$A$100<>""))),ROWS($1:1))),"")

Answer 2

Это очень легко с колонкой "помощник". В D1 введите:

=IF(ISERROR(MATCH(A1,$B$1:$B$5,0)),1,"")

и в D2 введите:

=IF(ISERROR(MATCH(A2,$B$1:$B$5,0)),1+MAX($D$1:D1),"")

и скопировать вниз. Столбец D отмечает каждую строку, содержащую полезные данные, с уникальным идентификатором. Столбец D говорит использовать сначала получить данные из строки № 1, затем получить данные из строки № 2, а затем получить данные из строки № 4

Затем в С1 введите:

=IFERROR(INDEX($A$1:$A$5,MATCH(ROWS($1:1),D:D,0)),"")

и скопируйте вниз:

Answer 3

Я хотел бы предложить вам простую формулу VLOOKUP, в которой будут сравниваться столбцы A и B и извлекаться уникальные значения в столбце C.

=IF(ISNA(VLOOKUP(A2,$B$2:$B$6,1,FALSE)),A2,"")

Надеюсь, это поможет вам.