Элементы, закрепленные на панели задач, снова появляются после перезагрузки в Windows 10

Question

Мне просто нужно было перенастроить свой ноутбук, и я снова настраиваю его. Были некоторые элементы, прикрепленные к моей панели задач с изображения, и когда я открепляю их, они возвращаются после перезагрузки. Я видел много комментариев об очистке% AppData%\Microsoft\Internet Explorer\Quick Launch\User Pinned\TaskBar и удалении HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Taskband. Также заметки о c:\Users\Public\CompanyProfile (который не существует для меня). Ни один из этих трюков не сработал. Я даже создал новых пользователей и вижу ту же проблему в этом аккаунте. Еще один симптом, который я имею, заключается в том, что, когда я по умолчанию использую браузер Firefox, он перезагружается в IE после перезагрузки. Я проверил и не вижу никакой групповой политики, которая управляет этим поведением. У меня нет идей.

Установленные программы для прикрепления и элементы, которые я помещаю на рабочий стол, переживают перезагрузку. Осмотревшись, я попробовал пакетную программу, чтобы помочь, и заметил, что если я запускаю эти команды в DOS:

taskkill /f /im explorer.exe
start explorer.exe

Сбрасывает панель задач и файловые ассоциации.

Answer 1

У меня нет хорошего ответа для постоянного исправления. Однако я смог замаскировать проблему. Я закончил тем, что создал задачу для запуска при входе в систему. Эта задача запускает приведенный ниже сценарий и открепляет элементы от панели задач.

Option Explicit

Dim objFSO, objShell, objFile, objFolder, objFolderItem, colVerbs, objShellApp, objVerb
Dim strFileNameAndPath

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")
Set objShellApp = CreateObject("Shell.Application")

' ***********************************************
' Unpin Internet Explorer
' ***********************************************
strFileNameAndPath = objShell.ExpandEnvironmentStrings("%APPDATA%") & _
 "\Microsoft\Internet Explorer\Quick Launch\User Pinned\Taskbar\Internet Explorer.lnk"

 ' Verify the files exists.  If not, we are got and don't need to do Anything
If objFSO.FileExists(strFileNameAndPath) Then
    set objFile = objFSO.GetFile(strFileNameAndPath)
    Set objFolder = objShellApp.Namespace(objFile.ParentFolder & "\")
    Set objFolderItem = objFolder.ParseName(objFile.Name)
    Set colVerbs = objFolderItem.Verbs
    For Each objVerb In colVerbs
        If LCase(Replace(objVerb.name, "&", "")) = "unpin from taskbar" Then objVerb.DoIt
    Next
End If

' ***********************************************
' Unpin Windows File Explorer
' ***********************************************
Set objFolder = objShellApp.Namespace("C:\ProgramData\Microsoft\Windows\Start Menu Places")

For each objFolderItem in objFolder.Items
    If InStr(1, objFolderItem.Name, "Explorer", vbTextCompare) > 0 Then
        objFolderItem.InvokeVerb("taskbarunpin")
    End If
Next

Set objVerb = Nothing
Set colVerbs = Nothing
set objFile = Nothing
Set objFolder = Nothing
Set objFolderItem = Nothing
Set objFSO = Nothing
Set objShell = Nothing
Set objShellApp = Nothing

Особая благодарность Syberdoor, который помог мне выяснить код проводника файлов (открепить File Explorer от панели задач в Windows 10 через скрипт или пакетный файл)