Сравните две колонки в разных книгах

Question

Я был бы признателен, если бы я мог получить некоторую помощь по проблеме, пытаясь создать макрос VBA. У меня есть две рабочие книги, и я хочу сравнить столбец "N" в рабочей книге 1 с столбцом "F" в рабочей книге 2. Затем, если есть совпадение, переходите к следующей ячейке вниз, если совпадений не найдено, я хочу скопировать следующую ячейку после столбца "F" в рабочей книге 2. Workbook 2 не будет иметь одно и то же имя, когда я получаю его каждое утро, но имя книги всегда начинается с "Copy of", поэтому я создал код ниже, чтобы выбрать его, используя частичное имя.

For Each ws In ActiveWorkbook.Worksheets
    If ws.Name Like "Copy of*" Then
        ws.Select
        Exit For
    End If
Next ws

Даже если я могу указать правильное направление, это было бы здорово.

Answer 1

Это объяснение не очень понятно

... если есть совпадение, переход к следующей ячейке вниз, если совпадений не найдено, я хочу скопировать следующую ячейку после столбца "F" в книге 2 ...

но попробуйте что-то вроде этого и измените его соответственно

---

Option Explicit

Public Sub CompareWorkBooks()
    Dim ws1 As Worksheet, ws2 As Worksheet

    Set ws1 = ThisWorkbook.Worksheets("Sheet1")
    Set ws2 = GetWSCopy("Copy of*")

    If Not ws2 Is Nothing Then

        Dim r As Long, cel As Range, found As Variant, ws2lr As Long

        optimizeXL True
        For r = ws1.UsedRange.Rows.Count To 1 Step -1
            Set cel = ws1.Cells(r, ws1.Columns("N").Column)
            If Len(cel.Value2) > 0 Then
                found = Application.Match(cel.Value2, ws2.UsedRange.Columns("F"), 0)

                If Not IsError(found) Then  'a match was found so move next cell down
                    cel.Offset(1).EntireRow.Insert xlDown
                Else    'match not found so copy row from ws1 to first empty row of ws2
                    ws2lr = ws2.UsedRange.Rows.Count + 1
                    ws1.UsedRange.Rows(cel.Row).EntireRow.Copy ws2.Cells(ws2lr, 1)
                End If
            End If
        Next
        optimizeXL False
    End If
End Sub

---

Private Function GetWSCopy(ByVal wsName As String) As Worksheet
    Dim ws As Worksheet
    For Each ws In ThisWorkbook.Worksheets
        If ws.Name Like wsName Then
            Set GetWSCopy = ws
            Exit Function
        End If
    Next
End Function

Public Sub optimizeXL(Optional ByVal settingsOff As Boolean = True)
    With Application
        .ScreenUpdating = Not settingsOff
        .Calculation = IIf(settingsOff, xlCalculationManual, xlCalculationAutomatic)
        .EnableEvents = Not settingsOff
    End With
End Sub

---

Кроме того, вы имеете в виду 2 книги (файлы),
но ваш код относится к рабочим листам (вкладки в той же рабочей книге)