Формула Excel для дубликатов

Question

Может ли кто-нибудь любезно показать мне формулу, необходимую для создания точных данных, которые у меня есть в столбце C:

Любые повторяющиеся ячейки в столбце B копируют sku из столбца A в столбец C.

Надеюсь, я объяснил это хорошо !!

Answer 1

Если у вас нет Office 365 Excel, вам понадобится UDF. Поместите этот код в модуль, прикрепленный к книге:

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    If TEXTJOIN <> "" Then 
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim)) 
    Else
        TEXTJOIN = ""
    End IF
End Function

Тогда следующая формула массива будет делать то, что вы хотите:

=TEXTJOIN(" | ",TRUE,IF($A$2:$A$11<>A2,IF($B$2:$B$11=B2,$A$2:$A$11,""),""))

Будучи формулой массива, она должна быть подтверждена с помощью Ctrl-Shift-Enter вместо Enter при выходе из режима редактирования. Если все сделано правильно, тогда Excel поместит {} вокруг формулы.

---

Если у вас Office 365 Excel, просто используйте приведенную выше формулу в качестве формулы массива, нет необходимости в UDF.

UDF имитирует функциональность TEXTJOIN.