Как я могу узнать, когда мой ноутбук последний раз отключался в Windows 10?

Question

Мне нужно знать, как долго мой ноутбук был отключен. Есть ли способ сделать это, используя cmd или какой-то инструмент?

Answer 1

Вы можете создать отчет о батарее, который будет содержать эту информацию. Это ручной процесс, который подходит для одноразовых проверок, но не подходит для постоянных повторных проверок.

Процесс прост.

1. Откройте командную строку от имени администратора.
2. Введите в powercfg /batteryreport /output "C:\batteryreport.html" и нажмите Enter.
3. Откройте файл отчета с помощью веб-браузера.

Отчет будет содержать историю состояний питания вашего компьютера и источника питания во время этого состояния.

Примечание: я получил эту информацию из быстрого поиска в Google и этого полезного документа, в котором много картинок: http://www.windowscentral.com/generate-battery-report-windows-10 Я сам протестировал ее на планшете под управлением Windows 10 сборка 1607 (юбилейное обновление).

Answer 2

Мне нужно знать, как долго мой ноутбук был отключен

Windows не регистрирует события, когда ноутбук отключен от сети.

Однако вы можете использовать что-то вроде командного файла ниже и создать собственное событие.

---

Battery.cmd

Этот пакетный файл отслеживает, работает ли ноутбук в данный момент от сети или от батареи.

Он создает пользовательское событие, если сеть отключена и ноутбук начинает использовать батарею.

@echo off
setlocal EnableDelayedExpansion
:start
rem get the battery status, 1 = battery discharging 2 = on mains
rem use findstr to strip blank lines from wmic output

for /f "usebackq skip=1" %%i in (`wmic path win32_battery get batterystatus ^| findstr /r /v "^$"`) do (
  set _status=%%i
  if [!_status!] equ [1] (
    rem on battery
    rem create a custom event in the application event log
    rem requires administrator privileges 
    eventcreate /l APPLICATION /t WARNING /ID 999 /D "Mains has been disconnected"
    goto :done
    ) else (
    rem on mains
    rem wait for 10 minutes then try again
    timeout /t 600 /nobreak > nul
    goto :start
    )
  )
:done
endlocal

Заметки:

• Команда Eventcreate работает в Windows XP до Windows 10 включительно, для работы требуются права администратора
• Если сеть отключена, в журнале событий ПРИЛОЖЕНИЯ будет сгенерировано событие с идентификатором 999 с описанием « Mains has been disconnected
• Измените команду eventcreate как требуется для вашей ситуации.
• Измените задержку timeout в соответствии с вашей ситуацией.

Пример вывода

При запуске Battery.cmd и отключении питания от сети генерируется следующий выход:

> battery

SUCCESS: An event of type 'WARNING' was created in the 'APPLICATION' log with 'EventCreate' as the source.

>

И вот новая запись в журнале событий:

---

Дальнейшее чтение

• Индекс AZ командной строки Windows CMD - Отличный справочник по всем вопросам, связанным с командной строкой Windows.
• Eventcreate
• Использование Windows PowerShell для определения того, работает ли ноутбук от батареи
• wmic - команда инструментария управления Windows.