Как заархивировать файлы отдельно (каждый файл) в папку, используя 7-zip?

Question

Я использую 7-zip в Windows 7 и пытаюсь создать пакет для автоматического zip-файла в папке.

Я хочу, чтобы каждый из файлов в папке был заархивирован отдельно.

Можете ли вы посмотреть в моем коде и предложить, как это сделать лучше всего?

Мне удалось заархивировать все это из одной папки в другую, но мне также нужно сделать каждый файл отдельно:

@ECHO OFF
SET hr=%time:~0,2%
IF %hr% lss 10 SET hr=0%hr:~1,1%

Set TODAY=%date:~4,2%-%date:~7,2%-%date:~10,4%-%hr%%time:~3,2%%time:~6,2%%time:~9,2%

ECHO.

ECHO Compressing files and folders in C:\zipush drive and moving to C:\new
ECHO.
7za a -tzip "C:\new-drive-%TODAY%.zip" "C:\zipush*" -mx5
ECHO.

ECHO Delete the files in orginal folder 
DEL "C:\zipush\*.*"
PAUSE

Answer 1

Ниже описано, что нужно сделать, чтобы завершить цикл, чтобы сжать каждый файл в свой собственный zip-файл с соглашением об именах <orignalfilename>.<extension>.zip , а затем удалить оригинал, если zip предыдущего файла был успешным. Вы можете изменить %%~NXA.zip на %%~NA.zip чтобы не включать оригинальное расширение имени файла в новый файл zip, если это необходимо.

Вы также должны убедиться, что каталог назначения создан, если он еще не существует, чтобы команды архивирования работали, как и ожидалось в цикле, поэтому я добавил это в логику сценария и также установил каталоги источника и назначения в качестве переменных сверху.

Я также использовал пакетные замены через цикл FOR, чтобы позаботиться об отдельных zip и именах файлов. Посмотрите дополнительные ресурсы из некоторых учебных материалов по этой теме (FOR /?).

---

Пример скрипта

@ECHO OFF
SET hr=%time:~0,2%
IF %hr% lss 10 SET hr=0%hr:~1,1%

SET TODAY=%date:~4,2%-%date:~7,2%-%date:~10,4%-%hr%%time:~3,2%%time:~6,2%%time:~9,2%

SET SrcDir=C:\zipush
SET DestDir=C:\new-drive-%TODAY%
IF NOT EXIST "%DestDir%" MD "%DestDir%"

ECHO.

ECHO Compressing files and folders in C:\zipush drive and moving to C:\new
ECHO.

ECHO Compressing files and folders in C:\zipush drive and moving to C:\new and then delete from C:\zipush
ECHO.
FOR %%A IN ("%SrcDir%\*.*") DO 7za a -tzip "%DestDir%\%%~NXA.zip" "%%~A" -mx5 && DEL /Q /F "%%~A"
ECHO.
PAUSE

---

Дополнительные ресурсы

• ЗА
• Условное исполнение

• Мэриленд

• FOR /? из командной строки

  In addition, substitution of FOR variable references has been enhanced.
  You can now use the following optional syntax:
  
  %~I         - expands %I removing any surrounding quotes (")
  %~fI        - expands %I to a fully qualified path name
  %~dI        - expands %I to a drive letter only
  %~pI        - expands %I to a path only
  %~nI        - expands %I to a file name only
  %~xI        - expands %I to a file extension only
  %~sI        - expanded path contains short names only
  %~aI        - expands %I to file attributes of file
  %~tI        - expands %I to date/time of file
  %~zI        - expands %I to size of file
  %~$PATH:I   - searches the directories listed in the PATH
                 environment variable and expands %I to the
                 fully qualified name of the first one found.
                 If the environment variable name is not
                 defined or the file is not found by the
                 search, then this modifier expands to the
                 empty string