Создать значение ячеек на основе формулы в Excel VBA

Question

У меня есть лист Excel, подобный этому, есть ли способ получить значение в C8, используя C6 в VBA?

Answer 1

Не VBA метод:

Назовите диапазоны по их особенностям

Итак, C2 будет x , C3 будет y и ...

Чтобы сделать это быстро:

1. Выделите B2:C4

2. На вкладке «Формула» нажмите « Create from Selection

3. Выберите Left затем нажмите ОК

Это назовет выделенные ячейки в столбце C; х, у, z соответственно.

Тогда ваша формула в C6 будет:

=x*y*1000/z

Тогда в С8:

=FORMULATEXT(C6)

---

Если это не сработает, то следующие UDF будут делать то, что вы хотите:

Function Foo(rng As Range) As String
    Dim MathArr()
    'Add to this array as needed to find all the math functions
    MathArr = Array("*", "-", "+", "/", "(", ")")

    Dim strArr() As String
    Dim temp As String
    Dim strFormula As String
    Dim i As Long

    'Hold two versions of the formula, one manipulate and the other to use.
    strFormula = rng.Formula
    temp = rng.Formula

    'Replace all math functions with space
    For i = LBound(MathArr) To UBound(MathArr)
        strFormula = Replace(strFormula, MathArr(i), " ")
    Next i

    'Split on the space
    strArr = Split(strFormula)

    'iterate and test each part if range
    For i = LBound(strArr) To UBound(strArr)
        If test1(strArr(i)) Then
            'If range then we repace that with the value to the right of that range
            temp = Replace(temp, strArr(i), Range(strArr(i)).Offset(, -1).Value)
        End If
    Next i

    'Return text
    Foo = "=" & temp

End Function

Function test1(reference As String) As Boolean
Dim v As Range

' if the string is not a valid range it will throw and error
On Error Resume Next
Set v = Range(reference) 'try to use referenced range, is address valid?
If Err.Number > 0 Then
    Exit Function 'return false
End If
On Error GoTo 0
test1 = True
End Function

Без названных диапазонов, поэтому формула в C6 равна =C2*C3*1000/C4 , я поместил это в C8:

=Foo(C6)