MS word: макрос для включения / выключения некоторых настроек проверки

Question

Какой макрос может включать / выключать некоторые настройки проверки? (К сожалению, запись макроса не записывает изменение настроек)

Я ищу способ включить / выключить 2 настройки проверки (одновременно):

• проверять орфографию при вводе
• помечать грамматические ошибки при вводе

Answer 1

Заявка.Опции.CheckGrammarAsYouType &.CheckSpellingAsYouType - это то, что вы ищете.

Пример:

Sub GrammarSpellingOn()
    Application.Options.CheckGrammarAsYouType = True
    Application.Options.CheckSpellingAsYouType = True
End Sub

Sub GrammarSpellingOff()
    Application.Options.CheckGrammarAsYouType = False
    Application.Options.CheckSpellingAsYouType = False
End Sub

Чтобы включить / выключить этот же макрос, во всплывающем окне указано, что изменение сделано:

Sub GrammarSpellingOnOff()
    If Application.Options.CheckGrammarAsYouType = True Or Application.Options.CheckSpellingAsYouType = True Then
        Application.Options.CheckGrammarAsYouType = False
        Application.Options.CheckSpellingAsYouType = False
        Call MsgBox("Grammar & Spell Checking turned OFF")
    Else
        Application.Options.CheckGrammarAsYouType = True
        Application.Options.CheckSpellingAsYouType = True
        Call MsgBox("Grammar & Spell Checking turned ON")
    End If
    Application.ScreenRefresh 'refresh to add/remove spellchecker underlines
End Sub

Answer 2

Так что я настроил его немного по-другому. Я в основном использую его, когда пишу презентации, в которых есть код. Я назначил макросы клавишам, и вот оба макроса:

Это будет игнорировать все проверки, поэтому избавляется от этих раздражающих маркеров из Word

    Sub CodeFont()
'
' CodeFont Macro
' Change font to differentiate code
'
    Selection.Font.Name = "Consolas"
    Selection.Font.Size = 11
    Selection.Font.ColorIndex = wdBlue
    Selection.NoProofing = True
End Sub

И когда я хочу вернуться к "нормальной" печати

Sub Normal()
'
' Normal Macro
'
'
    Selection.Font.Name = "Times New Roman"
    Selection.Font.Size = 12
    Selection.Font.ColorIndex = wdBlack
    Selection.NoProofing = False
End Sub