Пакетное переименование файла с суффиксом как случайный алфавитно-цифровой

Question

Вот код, который переименовывает все файлы в папке в алфавитно-цифровой.

@echo off
setlocal disableDelayedExpansion
set "chars=ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
for /f "eol=: delims=" %%F in ('dir /b /a-d *.jpg') do call :renameFile "%%F"
exit /b

:renameFile
setlocal enableDelayedExpansion
:retry
set "name="
for /l %%N in (1 1 8) do (
  set /a I=!random!%%36
  for %%I in (!I!) do set "name=!name!!chars:~%%I,1!"
)
echo if exist !name!.jpg goto :retry
endlocal & ren %1 %name%.jpg

Все, что вам нужно сделать, это скопировать / вставить этот код и сохранить его .bat файл и поместить в любые папки, где вы хотите переименовать файлы.

Вот как это работает:

пример: если имя файла - lenovo-wallpaper.jpg, то оно переименует его в AF45ASLJ.JPG

То, что я хочу, это имя файла +alphanumeric.jpg

пример: если имя файла - lenovo-wallpaper.jpg, то это должно быть lenovo-wallpaper-adfs45fad1.jpg

Answer 1

Измените последние две строки из

echo if exist !name!.jpg goto :retry
endlocal & ren %1 %name%.jpg

в

echo if exist %~n1+!name!.jpg goto :retry
endlocal & ren %1 %~n1+%name%.jpg

%~n1 получит имя файла без расширения, а затем просто добавит + перед новым именем переменной.

РЕДАКТИРОВАТЬ: полный пакет с заглавной буквы первой буквы и захвата файлов JPG, BMP, PNG и GIF

@echo off
setlocal disableDelayedExpansion
set "chars=ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
for /f "eol=: delims=" %%F in ('dir /b /a-d *.jpg *.png *.bmp *.gif') do call :renameFile "%%F"
exit /b

:renameFile
setlocal enableDelayedExpansion
:retry
set "name="
for /l %%N in (1 1 8) do (
  set /a I=!random!%%36
  for %%I in (!I!) do set "name=!name!!chars:~%%I,1!"
)
echo if exist %~n1+!name!.jpg goto :retry
call :FirstUp result %~n1
endlocal & ren %1 %result%+%name%.*

exit /b

:FirstUp
setlocal EnableDelayedExpansion
set "temp=%~2"
set "helper=##AABBCCDDEEFFGGHHIIJJKKLLMMNNOOPPQQRRSSTTUUVVWWXXYYZZ"
set "first=!helper:*%temp:~0,1%=!"
set "first=!first:~0,1!"
if "!first!"=="#" set "first=!temp:~0,1!"
set "temp=!first!!temp:~1!"
(
    endlocal
    set "result=%temp%"
    goto :eof
)