Мне нужно изменить текст, который вставляется, когда я использую цитату вставки> добавить новый источник.
По умолчанию вы получаете (Author,Year) .
Я хотел бы иметь возможность изменить это свободно. В идеале я хотел бы получить Title, Author, Year без скобок.
Ни один из доступных стилей Цитирования и Библиографии не соответствует тому, что я ищу.
Как мне получить то, что мне нужно? Нужно ли создавать новый стиль? Если так, то как мне это сделать?
Ниже показано, как создать базовый пользовательский стиль библиографии в Word. Ссылка также содержит инструкции по созданию более сложных стилей.
Сначала создайте основной стиль библиографии, которому будет следовать пользовательский стиль. Установить стиль библиографии
Чтобы создать стиль библиографии, мы создадим таблицу стилей XML; то есть, файл
.xslназываетсяMyBookStyle.xslиспользуя ваш любимый редактор XML.Notepadподойдет. Как следует из названия, наш пример будет стилем типа «книга».В верхней части файла добавьте следующий код:
<?xml version="1.0" ?>
<!--List of the external resources that we are referencing-->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:b="http://schemas.openxmlformats.org/officeDocument/2006/bibliography">
<!--When the bibliography or citation is in your document, it's just HTML-->
<xsl:output method="html" encoding="us-ascii"/>
<!--Match the root element, and dispatch to its children-->
<xsl:template match="/">
<xsl:apply-templates select="*" />
</xsl:template>
Как показывают комментарии, Word использует HTML для представления библиографии или цитирования в документе. Большая часть предыдущего XML-кода является просто подготовкой к более интересным частям стиля. Например, вы можете присвоить вашему стилю номер версии для отслеживания внесенных изменений, как показано в следующем примере.
<!--Set an optional version number for this style-->
<xsl:template match="b:version">
<xsl:text>2006.5.07</xsl:text>
</xsl:template>
Что еще более важно, вы можете дать своему стилю имя. Добавьте этот тег:
<xsl:when test="b:StyleNameLocalized">; а затем присвойте своему стилю имя на выбранном вами языке, используя следующий код.
<xsl:when test="b:StyleNameLocalized/b:Lcid='1033'">
<xsl:text>[Your Style Name]</xsl:text>
</xsl:when>
Этот раздел содержит название локали вашего стиля. В нашем примере файла мы хотим, чтобы имя нашего пользовательского стиля библиографии «Простой стиль книги» отображалось в раскрывающемся списке «Стиль» на вкладке «Ссылки». Для этого добавьте следующий код XML, чтобы указать, что имя стиля должно быть в английской локали (Lcid определяет язык).
<!--Defines the name of the style in the References dropdown list-->
<xsl:when test="b:StyleNameLocalized">
<xsl:choose>
<xsl:when test="b:StyleNameLocalized/b:Lcid='1033'">
<xsl:text>Simple Book Style</xsl:text>
</xsl:when>
</xsl:when>
Ваш стиль теперь будет отображаться под собственным именем в раскрывающемся списке «Стиль библиографии» в приложении.
Теперь рассмотрим детали стиля. Каждый тип источника в Word (например, книга, фильм, статья в периодическом издании и т.д.) Имеет встроенный список полей, которые можно использовать для библиографии. Чтобы просмотреть все поля, доступные для данного типа источника, на вкладке «Ссылки» выберите «Управление источниками», а затем в диалоговом окне «Диспетчер источников» выберите «Создать», чтобы открыть диалоговое окно «Создать источник». Затем выберите «Показать все поля библиографии».
Тип источника книги имеет следующие поля:
- автор
- заглавие
- Год
- город
- Штат / провинция
- Страна / Регион
- издатель
- редактор
- объем
- Количество томов
- Переводчик
- Краткое название
- Стандартный номер
- страницы
- Издание
- Комментарии
В коде вы можете указать поля, которые важны для вашего стиля библиографии. Даже когда флажок «Показать все поля библиографии» снят, эти поля будут отображаться, и рядом с ними будет стоять красная звездочка. В нашем примере с книгой я хочу убедиться, что автор, название, год, город и издатель введены, поэтому я хочу, чтобы рядом с этими полями появилась красная звездочка, чтобы предупредить пользователя о том, что это рекомендуемые поля, которые следует заполнить ,
<!--Specifies which fields should appear in the Create Source dialog box when in a collapsed state (The Show All Bibliography Fields check box is cleared)-->
<xsl:template match="b:GetImportantFields[b:SourceType = 'Book']">
<b:ImportantFields>
<b:ImportantField>
<xsl:text>b:Author/b:Author/b:NameList</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:Title</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:Year</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:City</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:Publisher</xsl:text>
</b:ImportantField>
</b:ImportantFields>
</xsl:template>
Текст в тегах
<xsl:text>является ссылкой на файлSources.xml. Эти ссылки извлекают данные, которые будут заполнять каждое из полей. ИзучитеSources.xml(%APPDATA%\Microsoft\Bibliography\Sources.xml), чтобы получить лучшее представление о том, как эти ссылки соответствуют тому, что находится в файле XML.Дизайн макета
Выходные данные для библиографий и цитат представлены в документе Word в виде HTML, поэтому, чтобы определить, как наши пользовательские стили библиографии и цитирования должны выглядеть в Word, нам нужно будет добавить немного HTML в нашу таблицу стилей.
Предположим, вы хотите отформатировать каждую запись в вашей библиографии следующим образом:
Last Name, First Name. (Year). Title. City: PublisherHTML-код, необходимый для этого, будет встроен в вашу таблицу стилей следующим образом.
<!--Defines the output format for a simple Book (in the Bibliography) with important fields defined-->
<xsl:template match="b:Source[b:SourceType = 'Book']">
<!--Label the paragraph as an Office Bibliography paragraph-->
<p>
<xsl:value-of select="b:Author/b:Author/b:NameList/b:Person/b:Last"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="b:Author/b:Author/b:NameList/b:Person/b:First"/>
<xsl:text>. (</xsl:text>
<xsl:value-of select="b:Year"/>
<xsl:text>). </xsl:text>
<i>
<xsl:value-of select="b:Title"/>
<xsl:text>. </xsl:text>
</i>
<xsl:value-of select="b:City"/>
<xsl:text>: </xsl:text>
<xsl:value-of select="b:Publisher"/>
<xsl:text>.</xsl:text>
</p>
</xsl:template>
Когда вы ссылаетесь на источник книги в своем документе Word, Word должен получить доступ к этому HTML, чтобы он мог использовать собственный стиль для отображения источника, поэтому вам придется добавить код в свою таблицу пользовательских стилей, чтобы Word мог сделать это.
<!--Defines the output of the entire Bibliography-->
<xsl:template match="b:Bibliography">
<html xmlns="http://www.w3.org/TR/REC-html40">
<body>
<xsl:apply-templates select ="b:Source[b:SourceType = 'Book']">
</xsl:apply-templates>
</body>
</html>
</xsl:template>
Аналогичным образом, вы должны будете сделать то же самое для вывода цитаты. Следуйте шаблону (Автор, Год) для отдельного цитирования в документе.
<!--Defines the output of the Citation-->
<xsl:template match="b:Citation/b:Source[b:SourceType = 'Book']">
<html xmlns="http://www.w3.org/TR/REC-html40">
<body>
<!-- Defines the output format as (Author, Year)-->
<xsl:text>(</xsl:text>
<xsl:value-of select="b:Author/b:Author/b:NameList/b:Person/b:Last"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="b:Year"/>
<xsl:text>)</xsl:text>
</body>
</html>
</xsl:template>
Закройте файл со следующими строками.
<xsl:template match="text()" /> </xsl:stylesheet>
Сохраните файл как
MyBookStyle.XSLи поместите его в каталог стилей (%appdata%\Microsoft\Bibliography\Style). Перезапустите Word, и ваш стиль теперь находится в раскрывающемся списке стилей. Вы можете начать использовать свой новый стиль.