Скрипт для сохранения (закрепления) сайта на панели задач

Question

Я отчаянно ищу некоторые ссылки, которые могут помочь мне сохранить ярлык на веб-странице (скажем, msn.com) на панели задач. Я гуглил последние четыре дня и нашел только ссылки на то, как сохранить ярлыки в приложениях (notepad.exe или Iexplorer.exe).

Насколько я понимаю, сохранение любой веб-страницы состоит из двух шагов

1. Создание короткого пути
2. Сохранение ярлыка (.lnk) на панели задач.

Но как я могу сохранить ярлык для определенного файла (readme.txt / msn.com) на панели задач? Если у вас есть идеи, пожалуйста, поделитесь со мной.

Answer 1

ПОМНИТЕ - Windows предназначена для предотвращения поднятия программ пользователями. Панель задач и меню Пуск - это пользователи.

Этот скрипт перечисляет и запускает глаголы для объекта оболочки (только файлы этой версии). Запустите без параметров, чтобы получить помощь (или прочитайте первые три строки).

Я называю это ShVerb.vbs - вы можете адаптировать его к ярлыку r/ ca и выбрать «Добавить на панель задач» (возможно - у меня Vista - последняя из подходящих ОС пользовательского интерфейса).

HelpMsg = vbcrlf & "  ShVerb" & vbcrlf & vbcrlf & "  David Candy 2014" & vbcrlf & vbcrlf & "  Lists or runs an explorer verb (right click menu) on a file or folder" & vbcrlf  & vbcrlf & "    ShVerb <filename> [verb]" & vbcrlf & vbcrlf & "  Used without a verb it lists the verbs available for the file or folder" & vbcrlf & vbcrlf
HelpMsg = HelpMsg & "  The program lists most verbs but only ones above the first separator" & vbcrlf & "  of the menu work when used this way" & vbcrlf & vbcrlf 
HelpMsg = HelpMsg & "  The Properties verb can be used. However the program has to keep running" & vbcrlf & "  to hold the properties dialog open. It keeps running by displaying" & vbcrlf & "  a message box." 
Set objShell = CreateObject("Shell.Application")
Set Ag = WScript.Arguments 
set WshShell = WScript.CreateObject("WScript.Shell") 
Set fso = CreateObject("Scripting.FileSystemObject")

    If Ag.count = 0 then 
        wscript.echo "  ShVerb - No file specified"
        wscript.echo HelpMsg 
        wscript.quit
    Else If Ag.count = 1 then 
        If LCase(Replace(Ag(0),"-", "/")) = "/h" or Replace(Ag(0),"-", "/") = "/?" then 
            wscript.echo HelpMsg 
            wscript.quit
        End If
    ElseIf Ag.count > 2 then 
        wscript.echo vbcrlf & "  ShVerb - To many parameters" & vbcrlf & "  Use quotes around filenames and verbs containing spaces"  & vbcrlf
        wscript.echo HelpMsg 
        wscript.quit
    End If

    If fso.DriveExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetFileName(Ag(0)))
'       Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
        Set objFolderItem = objFolder.self
        msgbox ag(0)
    ElseIf fso.FolderExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
        Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
    ElseIf fso.fileExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
        Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
    Else
        wscript.echo "  ShVerb - " & Ag(0) & " not found"
        wscript.echo HelpMsg 
        wscript.quit
    End If

    Set objVerbs = objFolderItem.Verbs

    'If only one argument list verbs for that item

    If Ag.count = 1 then
        For Each cmd in objFolderItem.Verbs
            If len(cmd) <> 0 then CmdList = CmdList & vbcrlf & replace(cmd.name, "&", "") 
        Next
        wscript.echo mid(CmdList, 2)

    'If two arguments do verbs for that item

    ElseIf Ag.count = 2 then
        For Each cmd in objFolderItem.Verbs
            If lcase(replace(cmd, "&", "")) = LCase(Ag(1)) then 
                wscript.echo(Cmd.doit)
                Exit For
            End If
        Next
    'Properties is special cased. Script has to stay running for Properties dialog to show.
        If Lcase(Ag(1)) = "properties" then
            WSHShell.AppActivate(ObjFolderItem.Name & " Properties")
            msgbox "This message box has to stay open to keep the " & ObjFolderItem.Name & " Properties dialog open."
        End If  
    End If
End If

Это выдержка из программы, создающей ярлык

                Set SC = Sh.CreateShortcut(FolderMRUPath & "\" & CurrentDirName & ".lnk")
                SC.TargetPath = CurrentDirPath
                SC.Save
                SH.RegWrite MenuOrderKey, 0 , "REG_BINARY"
                wshshell.refreshmenu