Цветовые числа по-разному в Emacs

Question

Я хочу, чтобы цвета отличались от текстовых символов в emacs для любого режима, в котором находится emacs. Как мне изменить файл .emacs для этой цели? Я хотел бы, чтобы мои номера всегда отображались в розовом.

Gvim, кажется, уже встроил эту функцию.

Answer 1

Использование - активировать или деактивировать локально с помощью: M-x smilingbuddha-mode

Чтобы включить smilingbuddha-mode глобально, либо раскомментировать (global-smilingbuddha-mode) и перезапустить; или введите M-x global-smilingbuddha-mode (который будет действовать до перезагрузки).

Пожалуйста, не стесняйтесь изменять регулярное выражение в соответствии с вашими личными потребностями.

(define-minor-mode smilingbuddha-mode
  "Minor mode for highlighting numbers."
  :group 'smilingbuddha
  :lighter " :)"
  (cond
    (smilingbuddha-mode
      (when (not (or font-lock-mode global-font-lock-mode))
        (font-lock-mode 1))
      (font-lock-add-keywords nil
        (list (list "\\([0-9]+\\)" '(0 'smilingbuddha-pink-face t)) ))
      (message "Turned ON `smilingbuddha-mode`."))
    ((not smilingbuddha-mode)
      (font-lock-remove-keywords nil
        (list (list "\\([0-9]+\\)" '(0 'smilingbuddha-pink-face t)) ))
      (font-lock-fontify-buffer)
      (message "Turned OFF `smilingbuddha-mode`."))))

(defgroup smilingbuddha nil
  "Highlight numbers."
  :version "0.1"
  :group 'smilingbuddha)

(defface smilingbuddha-pink-face
  '((t (:foreground "black" :background "pink")))
  "Face for `smilingbuddha-pink-face`."
  :group 'smilingbuddha)

(defun turn-on-smilingbuddha-mode ()
(interactive)
  (smilingbuddha-mode 1))

(defun turn-off-smilingbuddha-mode ()
(interactive)
  (smilingbuddha-mode -1))

(define-globalized-minor-mode global-smilingbuddha-mode
  smilingbuddha-mode turn-on-smilingbuddha-mode)
;; (global-smilingbuddha-mode)