Повторные строки заголовка исчезают после обновления связанной таблицы в Word

Question

Я пытаюсь выяснить, как запретить Word удалить параметр "повторять как заголовок в верхней части каждой страницы" при обновлении связанной таблицы в Word. У меня ~ 300 связанных таблиц в одном документе из нескольких источников данных, поэтому каждый раз копирование и вставка таблиц в документ Word занимает много времени.

Я попытался выбрать параметр повтора строки в настройке страницы в Excel, но, похоже, это тоже не работает.

Есть ли способ, которым я мог бы либо скопировать все таблицы в Excel программно с помощью VBA, либо запретить Word удалять свойства таблицы при каждом обновлении связанных таблиц?

Answer 1

ХОРОШО. Поэтому я продолжил и написал макрос, который будет сохранять все свойства HeadingFormat для каждой строки в каждой таблице, обновлять все таблицы и затем повторно применять эти свойства форматирования. Макрос, кажется, работает довольно хорошо и должен использоваться для других приложений. Наслаждайтесь!

Public Sub UpdateTables()
'Get Table Formats
Dim i As Integer
Dim j As Integer

Dim tablecount As Integer
tablecount = ActiveDocument.Tables.Count

Dim tableformats() As Integer
ReDim tableformats(tablecount)

For i = 1 To tablecount
    j = 1
    Do While ActiveDocument.Tables(i).Rows(j).HeadingFormat = -1
        tableformats(i) = tableformats(i) + 1
        j = j + 1
    Loop
    'MsgBox (tableformats(i))
Next i

'Update Table References
ActiveDocument.Fields.Update

'Apply Table Formating to Updated Tables
For i = 1 To tablecount
    For j = 1 To tableformats(i)
        If ActiveDocument.Tables(i).Rows(j).HeadingFormat = 0 Then
            ActiveDocument.Tables(i).Rows(j).HeadingFormat = wdToggle
        End If
    Next j
Next i       
End Sub