Создать папку из нескольких определенных файлов, а затем переместить в нее несколько определенных файлов.

Question

У меня есть несколько файлов

07-01.jpg
07-02.jpg until
07-48.jpg


37-01.jpg
37-02.jpg
37-03.jpg until37-48.jpg

Я хочу создать папку

07, 08.... ,37

а затем переместить несколько файлов

07-01.jpg, 07-02.jpg, 07-03.jpg into folder 07
08-01.jpg, 08-02.jpg, 08-03.jpg into folder 08
37-01.jpg, 37-02.jpg, 37-03.jpg into folder 37
etc

как будет выглядеть пакетный скрипт для достижения этой цели?

Спасибо

Answer 1

Пакетный файл не требуется:

for %F in (*-*.jpg) do @for /f "delims=-" %A in ("%F") do @md "%A" 2>nul&move /y "%F" "%A" >nul

Удвойте проценты, если они используются в пакетном скрипте.

Answer 2

Это должно работать:

@echo off
setlocal enableextensions enabledelayedexpansion
rem parameter 1: first prefix (e.g 7)
rem parameter 2: last prefix (e.g 37)
rem parameter 3: max counter (e.g. 48)
FOR /L %%A IN (%1,1,%2) DO (
    rem arrange the padding
    set pre=0%%A
    set pre=!pre:~-2!
    rem create the folder
    mkdir !pre!
    FOR /L %%B IN (1,1,%3) DO (
        rem arrange the padding
        set num=0%%B
        set num=!num:~-2!
        rem file name
        set curr_file=!pre!-!num!.jpg
        rem ECHO !curr_file!
        move !curr_file! !pre!
    )
)

Сохраните в командном файле (например, store_files.bat) и вызовите его с соответствующими параметрами:

store_files.bat 7 37 48

-

Изменить: решение dbenham является более элегантным.