Разные действия в разных URL:s

Question

Я выучил этот скрипт

#IfWinActive, ahk_exe chrome.exe
   #u::send ^t
#IfWinActive, ahk_exe notepad.exe
   #u::send ^n
#IfWinActive, ahk_exe notepad++.exe
   #u::send ^!s

Так что теперь я могу получить один и тот же ключ для выполнения разных действий в разных программах. Но как насчет шага дальше: различные действия в разных URL-адресах в Chrome.

Например, на Toggl.com я хочу ^!е делать действие x, а на Checkvist.com я хочу ^!е делать действие у.

Я представляю себе что-то вроде

Send ^L
set clipboard to send ^c
Look if it matches with "toggl", if it does: do x.
Look if it matches with "checkvist", if it does: do y.

Answer 1

#IfWinActive, ahk_exe chrome.exe
   ^!vk45:: ; crtl+alt+e
      WinGetTitle, winTitle, % "A"
      If winTitle~="^Toggl\s"
         TrayTip,, % "first action"
      Else If winTitle~="^Checkvist:\s"
         TrayTip,, % "second action"
      Else
         TrayTip,, % "third action"
      winTitle:=""
      Return

Или же:

#IfWinActive, ahk_exe chrome.exe
   ^!vk45:: ; crtl+alt+e
      SendEvent, ^{vk4C} ; crtl+l
      clipContent:=ClipboardAll
      SendEvent, ^{Ins}
      ClipWait, .5
      If ErrorLevel
      {
         TrayTip, % "Error", % "Clipboard is empty!",, 3
         Clipboard:=clipContent
         Return
      }
      clipURL:=Clipboard
      Clipboard:=clipContent
      If clipURL~="toggl.com"
         TrayTip,, % "first action"
      Else If clipURL~="checkvist.com"
         TrayTip,, % "second action"
      Else
         TrayTip,, % "third action"
      clipURL:=""
      Return