Как быстро перемещаться / переключаться между функциями на emacs?

Question

Как быстро перемещаться / переключаться между функциями на emacs? Я ищу способ быстро перейти к функциям в Emacs. Для этого я использую поиск в emacs, но он слишком медленный и терпит неудачу. Например, мне нужно убедиться, что введена строка, которая не будет соответствовать прототипу функции или вызову функции. Мне нужно включить в него тип функции и указание типа параметров ... и в зависимости от стиля синтаксиса кодирования, используемого в программе, это трудно / незаметно сделать. Что именно я ищу: что-то, что я набираю только имя функции и переходить к ней. Мой текущий язык - C на Linux. Но если есть такая возможность для других языков программирования и платформ, пожалуйста, покажите мне. Буду очень признателен.

Пожалуйста: не предлагайте "использовать IDE", я в порядке с emacs.

Answer 1

M-x imenu позволяет переходить к функциям в одном файле. Я связал его с Super-I для легкого доступа.

Answer 2

Я использую cscope интегрированный в Emacs, и он отлично работает для поиска функций, переменных и т.д. И перемещения между ними.

Редактировать: в .emacs (или .xemacs/init.el) у меня есть:

(require 'xcscope)
(setq cscope-do-not-update-database t)

Затем я просто вручную запускаю cscope для исходных файлов (для ядра Linux make cscope , который также работает во многих других крупных проектах).

Answer 3

Как уже было предложено другими, я также использую Imenu исключительно для навигации в буфере. Я нахожу это очень полезным, имея интерфейс ido для Imenu. вот мой конфиг для ido-imenu . (это слегка измененная версия функции, которую вы найдете на странице emacswiki)

(defun ido-imenu ()
  "Update the imenu index and then use ido to select a symbol to navigate to.
Symbols matching the text at point are put first in the completion list."
  (interactive)
  (imenu--make-index-alist)
  (let ((name-and-pos '())
        (symbol-names '()))
    (flet ((addsymbols
            (symbol-list)
            (when (listp symbol-list)
              (dolist (symbol symbol-list)
                (let ((name nil) (position nil))
                  (cond
                   ((and (listp symbol) (imenu--subalist-p symbol))
                    (addsymbols symbol))

                   ((listp symbol)
                    (setq name (car symbol))
                    (setq position (cdr symbol)))

                   ((stringp symbol)
                    (setq name symbol)
                    (setq position
                          (get-text-property 1 'org-imenu-marker symbol))))

                  (unless (or (null position) (null name))
                    (add-to-list 'symbol-names name)
                    (add-to-list 'name-and-pos (cons name position))))))))
      (addsymbols imenu--index-alist))
    ;; If there are matching symbols at point, put them at the beginning
    ;; of `symbol-names'.
    (let ((symbol-at-point (thing-at-point 'symbol)))
      (when symbol-at-point
        (let* ((regexp (concat (regexp-quote symbol-at-point) "$"))
               (matching-symbols
                (delq nil (mapcar
                           (lambda (symbol)
                             (if (string-match regexp symbol) symbol))
                           symbol-names))))
          (when matching-symbols
            (sort matching-symbols (lambda (a b) (> (length a) (length b))))
            (mapc
             (lambda (symbol)
               (setq symbol-names (cons symbol (delete symbol symbol-names))))
             matching-symbols)))))
    (let* ((selected-symbol (ido-completing-read "Symbol? " symbol-names))
           (position (cdr (assoc selected-symbol name-and-pos))))
      (push-mark)
      (if (overlayp position)
          (goto-char (overlay-start position))
        (goto-char position)))))

(global-set-key (kbd "C-x C-i") 'ido-imenu)

И я могу использовать Cx Ci во многих режимах языков, которые поддерживают imenu