Префикс всех строк с первым словом в файле

Question

Я хочу префикс всех строк файла (кроме первой строки), используя первое слово в файле.

Входные данные:

x.o: x.cpp /u/a.h 
/b.h \
/c.h \

выход:

x.o: x.cpp /u/a.h \
x.o: /b.h \
x.o: /c.h \

Может кто-нибудь, пожалуйста, помогите мне, как решить вышеизложенное с помощью sed?

Answer 1

Вы можете сделать это так с помощью GNU sed:

sed -r '1 {h; s/ .*//; x}; 1!{G; s/([^\n]*)\n(.*)/\2 \1/}' infile

Или как отдельный скрипт:

parse.sed

1 {                         # run block for first line only
  h                         # save copy of line in hold space
  s/ .*//                   # remove redundant part
  x                         # swap prefix to hold space
}

1! {                        # when not first line
  G                         # append prefix to pattern space
  s/([^\n]*)\n(.*)/\2 \1/   # reorganize so prefix is the prefix
}

Запустите это так:

 sed -rf parse.sed infile

Выход:

x.o: x.cpp /u/a.h 
x.o: /b.h \
x.o: /c.h \

Answer 2

Perl решение:

perl -pe 'print $prefix; ($prefix) = /^(.+? )/ if 1..1' INPUT.TXT