Applescript для подключения к устройству Bluetooth

Question

Я пытаюсь создать appleScript, чтобы я мог подключиться к устройству Bluetooth по его идентификатору Bluetooth.

До сих пор мне удалось заставить appleScript включить Bluetooth, если он выключен. Вот код:

# This is only necessary, if AppleScripts are not yet allowed to change checkboxes
tell application "System Events" to set UI elements enabled to true
# Now change the bluetooth status
  tell application "System Preferences"
    set current pane to pane id "com.apple.preferences.bluetooth"
      tell application "System Events"
        tell process "System Preferences"
        # Enabled is checkbox number 2
        if value of checkbox 2 of window "Bluetooth" is 0 then
            click checkbox 2 of window "Bluetooth"
        end if
    end tell
end tell
quit
end tell

Кто-нибудь знает, можно ли и как настроить новое устройство Bluetooth и можно ли подключиться к устройству на основе его имени / идентификатора устройства Bluetooth?

Я также пытался записать действие в Automator, но для опции "настроить новое устройство" Automator просто говорит мне: "нажмите" "кнопку". Спасибо

Answer 1

Мне удалось сделать это благодаря этой ссылке, предоставленной @ mu3 в комментариях. Вот сценарий Apple:

activate application "SystemUIServer"
tell application "System Events"
    tell process "SystemUIServer"
        -- Working CONNECT Script.  Goes through the following:
        -- Clicks on Bluetooth Menu (OSX Top Menu Bar)
        --    => Clicks on device Item
        --      => Clicks on Connect Item
        set btMenu to (menu bar item 1 of menu bar 1 whose description contains "bluetooth")
        tell btMenu
            click
            tell (menu item "Beats Solo³ de Anthonin" of menu 1)
                click
                if exists menu item "Connect" of menu 1 then
                    click menu item "Connect" of menu 1
                    return "Connecting..."
                else
                    key code 53 -- Close main BT drop down if Connect wasn't present
                    return "Connect menu was not found, are you already connected?"
                end if
            end tell
        end tell
    end tell
end tell

Все, что вам нужно сделать, это заменить "Beats Solo³ de Anthonin" на имя вашего устройства, а если ваш компьютер не на английском языке, заменить "Connect" с переводом на ваш язык.

Надеюсь это поможет :)