Ваш вопрос хорош, потому что вы пытались решить свою проблему и показали нам, что вы пытались. Ваш вопрос плохой, потому что вы не говорите, что не так. Ваш макрос работает без ошибок. Я предполагаю, что это не делает то, что вы хотите, но вы не говорите нам, что вы хотите.
Я создал рабочий лист, который соответствует вашему макросу:
Я взял ваш код и сделал несколько небольших изменений:
- Я добавил
Option Explicit и объявил все переменные.
- Я добавил оператор, чтобы получить имя папки, содержащей мою книгу, и добавил это имя папки в оператор open. Возможно, вы включаете путь в рабочую таблицу и вам это не нужно.
,
Option Explicit
Sub CreateFile()
Dim fnum As Long
Dim MyFile As String
Dim PathCrnt As String
PathCrnt = ActiveWorkbook.Path & "\"
Do While Not IsEmpty(ActiveCell.Offset(0, 1))
MyFile = PathCrnt & ActiveCell.Value & ".mhd"
'set and open file for output
fnum = FreeFile()
Open MyFile For Output As fnum
'use Print when you want the string without quotation marks
Print #fnum, ActiveCell.Offset(0, 5); " " & ActiveCell.Offset(0, 6); " " & _
ActiveCell.Offset(0, 7); " " & ActiveCell.Offset(0, 8); " " & _
ActiveCell.Offset(0, 9); " " & ActiveCell.Offset(0, 10); " " & _
ActiveCell.Offset(0, 11); " " & ActiveCell.Offset(0, 12); " " & _
ActiveCell.Offset(0, 13); " " & ActiveCell.Offset(0, 14); " " & _
ActiveCell.Offset(0, 15); " " & ActiveCell.Offset(0, 16); " " & _
ActiveCell.Offset(0, 17); " " & ActiveCell.Offset(0, 18); " " & _
ActiveCell.Offset(0, 19); " " & ActiveCell.Offset(0, 20); " " & _
ActiveCell.Offset(0, 21); " " & ActiveCell.Offset(0, 22); " " & _
ActiveCell.Offset(0, 23); " " & ActiveCell.Offset(0, 24); " " & _
ActiveCell.Offset(0, 25); " " & ActiveCell.Offset(0, 26)
Close #fnum
ActiveCell.Offset(1, 0).Select
Loop
End Sub
Ваш макрос запустился без ошибок и создал файл в строке. Я согласен, что это не элегантно, но работает, если это то, что вы хотите. Интересно, хотите ли вы, чтобы все строки были в одном файле? Если это так, вам нужно открыть и закрыть файл вне цикла.
Ниже я привел ваш код в порядок, но не изменил, что он делает. Надеюсь, это поможет. Вернись, если какие-либо из моих объяснений неясны. Если это не дает вам достаточно информации для решения вашей проблемы, вам придется более подробно объяснить, что не так с вашим макросом.
Option Explicit
Sub CreateFile2()
Dim ColStart As Long
Dim ColCrnt As Long
Dim FileLine As String
Dim FileName As String
Dim fnum As Long
Dim MyFile As String
Dim PathCrnt As String
Dim RowStart As Long
Dim RowLast As Long
Dim RowCrnt As Long
' Your code starts at the active cell. This relies on the user leaving
' the cursor in the correct cell of the correct worksheet. I have left
' the macro like this but have made it more explicit.
ColStart = ActiveCell.Column
RowStart = ActiveCell.Row
PathCrnt = ActiveWorkbook.Path & "\"
' My code does not move the cursor and operates on the worksheet
' identified in the With statement. I have used the active worksheet
' but I could have written 'With Worksheets("Sheet2")' or
' made the worksheet name a variable.
With ActiveSheet
' Cells(R,C) identifies a cell within the active worksheet by its row
' and column number.
' .Cells(R,C) identifies a cell within the worksheet named in the With
' statement by its row and column number.
' Rows.Count gives the maximum row number in your version of Excel.
' This statement starts at the bottom of column ColStart, moves up until
' it reaches a cell with a value and returns its row number.
' With this I could write:
' For RowCrnt = RowStart to RowLast
' -----
' Next
' I have kept your style. But I suggest you experiment with Ctrl+Up,
' which is the keyboard equivalent of this VBA and look up "End" in
' VBA help.
RowLast = .Cells(Rows.Count, ColStart).End(xlUp).Row
RowCrnt = RowStart
Do While Not IsEmpty(.Cells(RowCrnt, ColStart).Value)
' This is not necessary; I can use .Cells(RowCrnt, ColStart).Value
' in the file open statment. But this makes it clearer what I am
' doing. When you need to update this macro in six or twelve
' months you will immediately see what the macro is doing.
FileName = .Cells(RowCrnt, ColStart).Value
' Why the extension "MHD"? It is easier to stick to standard
' extensions.
MyFile = PathCrnt & FileName & ".mhd"
'set and open file for output
fnum = FreeFile()
Open MyFile For Output As fnum
' There are lots of different ways of concatenating the cells in
' a row. I will not claim this is the best but I think it is easy
' to understand. Having it in a loop means it is easy to change
' the number of columns written to the file.
FileLine = .Cells(RowCrnt, 6).Value
For ColCrnt = 7 To 27
FileLine = FileLine & " " & .Cells(RowCrnt, ColCrnt).Value
Next
Print #fnum, FileLine
Close #fnum
RowCrnt = RowCrnt + 1
Loop
End With
End Sub
