Макрос - поиск работы, копирование и вставка строки

Question

Я хотел бы создать макрос, чтобы найти работу (используйте функцию поиска), а затем скопировать строку, на которой работа, и скопировать и вставить всю строку, включая значения и формулы.

Номер задания, которое нужно найти, будет меняться каждый раз, поэтому мне бы хотелось, чтобы появилось всплывающее окно, которое я могу заполнить, и произойдет сбой, если совпадений не будет.

Может ли кто-нибудь помочь?

Answer 1

Вот пример макроса VBA, с которого можно начать. Комментарии в коде для описания намерения. Вы можете добавить обработку ошибок в соответствии с вашими потребностями.

Sub CopyData()
    Dim res As String
    Dim cl As Range
    Dim sh As Worksheet

    ' operate on the active sheet
    Set sh = ActiveSheet

    ' ask for ID to find in column A
    res = InputBox("Enter ID to Find", "Copy Row")

    ' If no responce, exit
    If res = "" Then
        Exit Sub
    End If

    With sh
        ' Find first occurance
        Application.FindFormat.Clear
        Set cl = .Columns(1).Find(What:=res, _
            After:=.Cells(.Rows.Count, 1), _
            LookIn:=xlValues, _
            LookAt:=xlWhole, _
            SearchOrder:=xlByRows, _
            SearchDirection:=xlNext, _
            MatchCase:=True)

        If Not cl Is Nothing Then
            ' if found, select entire row
            Set cl = cl.EntireRow
            ' copy and insert paste data into next row
            cl.Copy
            cl.Offset(1, 0).Insert
            ' turn off copy highlight (moving border)
            Application.CutCopyMode = False
        End If
    End With
End Sub