Резюме Zsh-Terminal (OS X Lion)

Question

OS X Lion имеет функцию "Возобновить", т.е. при повторном открытии приложения оно восстанавливает все окна и их содержимое. Это работает и для Терминала. Но если вы используете Zsh вместо Bash, он не восстанавливает открытый каталог. Как я могу это исправить?

Answer 1

Вот моя адаптация /etc /bashrc для zsh. Я включил процентное кодирование всех символов URL, которые в нем нуждаются, что важно, если вы хотите, чтобы это работало со всеми допустимыми именами файлов и каталогов.

Кроме того, эта версия регистрирует хук chpwd вместо непосредственного определения chpwd. Это позволяет регистрировать более одной функции в других сценариях и файлах конфигурации.

# Tell the terminal about the working directory whenever it changes.
if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then

    update_terminal_cwd() {
        # Identify the directory using a "file:" scheme URL, including
        # the host name to disambiguate local vs. remote paths.

        # Percent-encode the pathname.
        local URL_PATH=''
        {
            # Use LC_CTYPE=C to process text byte-by-byte.
            local i ch hexch LC_CTYPE=C
            for ((i = 1; i <= ${#PWD}; ++i)); do
                ch="$PWD[i]"
                if [[ "$ch" =~ [/._~A-Za-z0-9-] ]]; then
                    URL_PATH+="$ch"
                else
                    hexch=$(printf "%02X" "'$ch")
                    URL_PATH+="%$hexch"
                fi
            done
        }

        local PWD_URL="file://$HOST$URL_PATH"
        #echo "$PWD_URL"        # testing
        printf '\e]7;%s\a' "$PWD_URL"
    }

    # Register the function so it is called whenever the working
    # directory changes.
    autoload add-zsh-hook
    add-zsh-hook chpwd update_terminal_cwd

    # Tell the terminal about the initial directory.
    update_terminal_cwd
fi

Answer 2

ОБНОВЛЕНИЕ: Это не совсем правильно, по причинам, указанным в комментариях. Используйте ответ ниже. Спасибо @ChrisPage за прохождение лишней мили :)

Ответ может быть найден путем обратного инжиниринга того, как bash делает это в /etc/bashrc . Я перепробовал множество подходов со всей сети, но путь Apple, кажется, работает лучше всего (см. Рисунок).

В вашем .zshrc добавьте следующее

# Set Apple Terminal.app resume directory
if [[ $TERM_PROGRAM == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]] {
  function chpwd {
    local SEARCH=' '
    local REPLACE='%20'
    local PWD_URL="file://$HOSTNAME${PWD//$SEARCH/$REPLACE}"
    printf '\e]7;%s\a' "$PWD_URL"
  }

  chpwd
}

Счастливого возобновления.

Для пояснения, этот ответ относится к загадочному сообщению в настройках Terminal X. Lion в OS X:

** Программы уведомляют Терминал о текущем рабочем каталоге, используя escape-последовательности. Возможно, вам придется настроить вашу оболочку или другие программы, чтобы включить это поведение.*

Этот ответ работает, когда вы используете zsh в качестве оболочки. Резюме терминала для bash уже реализовано Apple.