Пакетный экспорт выбранных видео с QuickTime Player 7 с использованием определенных настроек экспорта?

Question

Как я могу использовать appleScript или Automator для пакетного экспорта видеофайлов, которые я выбрал в Finder, но НЕ используя сервисный метод "Кодировать выбранные видеофайлы", который имеет только 4 формата на выбор?

По сути, мне нужно экспортировать видео либо с помощью "Самые последние настройки", выбранные в последний раз, когда я экспортировал видео из QuickTime 7, либо чтобы у меня была возможность указать настройки с помощью диалогового окна экспорта в QuickTime 7, чтобы выбрать конкретное форматирование. нужно для видео, которое я выбрал.

Иногда мне нужен кодек Apple ProRes 422 LT, а иногда мне нужно использовать обычный Apple ProRes 422. Я также должен убедиться, что частота кадров установлена на 30 независимо от частоты кадров исходного файла, а размеры будут 1280x720 или 1920x1080.

Наконец, мне также нужно будет установить разные параметры кодирования звука для разных видео.

Надеюсь, кто-то знает способ сделать это. Я копался здесь и в Google, и не смог понять это. Кажется, большая часть информации, которую я нахожу в Интернете, просто рассказывает людям, как использовать тот же метод, который использует сервис "Кодировать выбранные видеофайлы".

Answer 1

Эврика! Я нашел в Интернете рабочий процесс Automator, который на самом деле работает. Я просто должен был изменить его так, чтобы он принимал файлы фильмов вместо изображений. Он использует "Самые последние настройки" в QuickTime 7, поэтому мне просто нужно экспортировать первое видео вручную, чтобы правильно ввести введенные настройки, а остальное я могу просто выбрать и пакетировать. Ура!

Исходная страница, которую я нашел с информацией и файлом рабочего процесса, находится здесь:http://ptrbrtz.net/batch-convert-animated-gifs-to-videos-using-applescript-automator-quicktime-7-on-os-x/

Я также добавлю сценарий на тот случай, если страница, на которую я ссылаюсь, исчезнет. Это нужно просто добавить в Automator как службу, используя в качестве входных данных файлы фильмов из Finder.

А вот и AppleScript для добавления в сервис. Я только что сохранил сервис как "Export_mov_via_QuickTime7.workflow".

on run {inputFiles}
    if inputFiles is equal to {} then
        set inputFiles to (choose file with prompt "Select the file(s) to convert:" with multiple selections allowed without invisibles)
    end if
    open inputFiles
end run

on open droppedItems
    tell application "Finder" to set inputFolder to (container of first item of droppedItems) as Unicode text
    set outputFolder to (choose folder with prompt "Select output folder:" default location (inputFolder as alias)) as Unicode text

    display dialog "Most recent QuickTime 7 export settings will be used.
Existing files will be overwritten/moved to trash!
Beware of evil QT7 Gamma shift!"

    tell application "QuickTime Player 7"
        activate
        close every window
    end tell

    repeat with currentItem in droppedItems
        tell application "Finder" to set fileName to name of currentItem as Unicode text

        tell application "QuickTime Player 7"
            open currentItem
            tell front document to set frameCount to count of frames of first track
        end tell

        set outputFileName to (outputFolder & fileName & ".mov")

        tell application "Finder"
            if exists file outputFileName then
                delete file outputFileName
            end if
        end tell

        tell application "QuickTime Player 7"
            if frameCount is greater than 1 then
                with timeout of 86400 seconds -- 24 hours
                    export front document to outputFileName as QuickTime movie using most recent settings
                end timeout
            end if
            close front document
        end tell
    end repeat

    quit application "QuickTime Player 7"
end open

Теперь в любое время, когда вы хотите выполнить пакетный экспорт видео с помощью QuickTime Player 7 Pro с любыми настройками, которые вы выберете, вам просто нужно выбрать все другие видео, которые вы хотите экспортировать, выбрать сервис в меню Finder-> Services и насладиться кофе перерыв, пока все ваши видео конвертированы! = D